root/docs/yappo/devsumi2008/wiiremote.pl

use strict;
use warnings;

package MyWii;

use base qw/ Class::Accessor::Fast Mac::WiiRemote::Client /;
__PACKAGE__->mk_accessors(qw/
  path
  rf_base rb_base lf_base lb_base
  rf_last rb_last lf_last lb_last
  x_last
  last_scroll_time
/);

sub send_event {
    my($self, $msg) = @_;
    return if $self->last_scroll_time + 1 > time;

    warn "GO TO: $msg";
    $self->last_scroll_time(time);

    open my $fh, '>', $self->path or return;
    print $fh $msg;
    close $fh;
}

sub left  { shift->send_event('left') }
sub right { shift->send_event('right') }
sub up    { shift->send_event('left') }
sub down  { shift->send_event('right') }
sub home  { shift->send_event('home') }
sub end   { shift->send_event('end') }

sub connected {
    my($self, $c, $remote) = @_;

    for my $bl qw( base last ) {
        for my $rl qw( r l ) {
            for my $fb qw( f b ) {
                my $meth = "${rl}${fb}_${bl}";
                $self->$meth(0);
            }
        }
    }

    $self->x_last(0);
    $self->last_scroll_time(time);
    warn "connect";

    # $c->remote->setLEDEnabled1_enabled2_enabled3_enabled4(1,0,0,1); LED
}

sub expansion_port_changed {
    my($self, $c, $remote) = @_;
    return unless $remote->address eq $c->remote->address;

    if ($remote->isExpansionPortAttached) {
        warn "Expansion ENABLE";
        $remote->setExpansionPortEnabled(1);
    } else {
        warn "Expansion DISABLE";
        $remote->setExpansionPortEnabled(0);
    }
}

sub button_changed {
    my($self, $c, $button, $is_pressed) = @_;

    warn "$button, $is_pressed";

    $self->rf_base($self->rf_last);
    $self->rb_base($self->rb_last);
    $self->lf_base($self->lf_last);
    $self->lb_base($self->lb_last);

    if (!$is_pressed) {
        $self->right if $button eq 10;
        $self->left  if $button eq 9;
    }
}

sub acceleration_changed {
    my($self, $c, $d, $x, $y, $z) = @_;
    #    warn $self->remote->expansionPortType;
    # 右加速でx減少、左加速でx加算

    $self->right if $x > $self->x_last + 100;
    $self->left  if $x < $self->x_last - 100;

    $self->x_last($x);
}

sub barance_wii_board_changed {
    my($self, $c, $zero, $rf, $rb, $lf, $lb) = @_;
    #    my $calib = $self->remote->calcWeightRf_rb_lf_lb($rf, $rb, $lf, $lb);

    $self->rf_last($rf);
    $self->rb_last($rb);
    $self->lf_last($lf);
    $self->lb_last($lb);

    my $weight_rf = $rf - $self->rf_base;
    my $weight_rb = $rb - $self->rb_base;
    my $weight_lf = $lf - $self->lf_base;
    my $weight_lb = $lb - $self->lb_base;

    if (($weight_lf * 5) < $weight_rf && ($weight_lb * 5) < $weight_rb && ($weight_rf + $weight_rb) > 1000 && !$self->{fit_is_pressed}) {
        $self->{fit_is_pressed} = 1;
        $self->right;
    } elsif (($weight_rf * 5) < $weight_lf && ($weight_rb * 5) < $weight_lb && ($weight_lf + $weight_lb) > 1000 && !$self->{fit_is_pressed}) {
        $self->{fit_is_pressed} = 1;
        $self->left
    } elsif (($weight_rf + $weight_rb + $weight_lf + $weight_lb) < 1000) {
        $self->{fit_is_pressed} = 0;
    }
}

sub disconnected {
    my($self, $c, $device) = @_;
    $c->remote->release;
}

package main;

use Mac::WiiRemote;

my $wii = Mac::WiiRemote->new( MyWii->new({ path => '/tmp/devsumi-ctl.txt' }) );
NSRunLoop->currentRunLoop->run;