root/lang/actionscript/FPazzle/trunk/src/FPazzle.mxml @ 14660

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" creationComplete="init();">
        <mx:HBox styleName="keyword">
                <mx:HBox enabled="true" id="searchbox">
                        <mx:TextInput id="keyword" styleName="input" focusIn="onSearchFocus();" focusOut="onSearchLeave();" />
                        <mx:Button id="keywordSubmit" label="Search" click="flickrStart();" />
                </mx:HBox>
        <mx:Label id="imageUrl" selectable="true" />
        <mx:Label id="permalink" selectable="true" />
        </mx:HBox>

        <mx:Script>
                <![CDATA[
                import com.adobe.webapis.flickr.*;
                import com.adobe.webapis.flickr.events.*;
                import com.adobe.webapis.flickr.methodgroups.*;
                import net.suztomo.FPazzle.*;
                import net.suztomo.FPazzle.event.*;

                import flash.events.*;
                import flash.system.*;

                import mx.core.UIComponent;
                import mx.managers.*;
                import mx.controls.*;

                private var fls:FlickrService;
                private var loader:Loader;
                private var photo:Photos;
                private var img:BitmapData;
                private var flc:FlickrConnector;
                private var targetUrl:String;
                private var bgImage:MiniImage;
                private var bgImages:Array;
                private static var defaultInputText:String = "Enter Keyword";

                public static var container:UIComponent;

                private var board:FBoard;
                public function init():void {
                        flc = new FlickrConnector();
                        Security.loadPolicyFile("http://farm1.static.flickr.com/crossdomain.xml");
                        Security.loadPolicyFile("http://farm2.static.flickr.com/crossdomain.xml");
                        Security.loadPolicyFile("http://farm3.static.flickr.com/crossdomain.xml");
                        Security.loadPolicyFile("http://farm4.static.flickr.com/crossdomain.xml");
                        
                        addEventListener(KeyboardEvent.KEY_DOWN, onPressKey);
                        keyword.text = defaultInputText;
                        if (Application.application.parameters.url && Application.application.parameters.url.length > 5) {
                                targetUrl = Application.application.parameters.url
                                imageUrl.htmlText = '<a target="_blank" href="'+targetUrl+'">Flickr Photo Page</a>';
                                startLoadImage();
                        }
                        container = new UIComponent();
                        addChild(container);
                        
                        bgImages = new Array();
                }
                
                public function flickrStart():void {
                        if (keyword.text.length < 5) {
                                Alert.show("Please Input 5 or more charactors word", "Too short keyword");
                                return;
                        }
                        var word:String = keyword.text;
                        flc.setOnComplete(onFlickrImageComplete);
                        flc.loadImage(word, 0);
                        flc.addEventListener(FlickrConnector.NOT_FOUND, onNotFound);
                        searchbox.enabled = false;
                        CursorManager.setBusyCursor();
                }

                public function onFlickrImageComplete(event:Event): void
                {
                        img = event.target.content.bitmapData;
                        board = new FBoard(2, 2, img);
                        board.addEventListener(FBoard.BOARD_COMPLETE, onBoardComplete);
                        addChild(board);
                        board.photo = flc.tmpPhoto;
                        targetUrl = "http://flickr.com/photos/"+board.photo.ownerId+"/"+board.photo.id;
                        imageUrl.htmlText = '<font color="#61D2FF"><a target="_blank" href="'+targetUrl+'" >'+ 'View current photo on Flickr</a></font>';
/*                      permalink.htmlText = '  <font color="#61D2FF"><a target="_blank" href="http://suztomo.net/fp/?url='+board.photo.url+'">'
                                + 'Permalink to Pazzle</a></font>';*/
                        board.createPieces();

                        for each(var i:MiniImage in bgImages) {
                                i.down(img.height*0.6);
                        }

                        bgImage = new MiniImage(img);
                        bgImages.push(bgImage);
                        bgImage.bitmapData = event.target.content.bitmapData;
                        bgImage.scaleX = 0.6;
                        bgImage.scaleY = 0.6;
                        bgImage.x = 50;
                        bgImage.y = 100;
                        if (i != null) {
                                i.addCustomEventListener("moved", onMiniImageMoved);
                        } else {
                                container.addChild(bgImage);
                                bgImage.emerge();
                        }

                        CursorManager.removeBusyCursor();
                }

                private function onMiniImageMoved(e:Event):void
                {
                        bgImage.alpha = 0;
                        container.addChild(bgImage);
                        bgImage.emerge();
                }

                public function startLoadImage():void
                {
                        searchbox.enabled = false;
                        CursorManager.setBusyCursor();
                        loader = new Loader();
                        loader.addEventListener(Event.COMPLETE, onLoadTargetImage);
                        loader.load(new URLRequest(targetUrl), new LoaderContext(true));
                }

                private function onLoadTargetImage(event:Event):void
                {
                        trace(event.target.bitmapData);
                        board = new FBoard(3, 3, event.target.bitmapData);
                        addChild(board);
                        board.createPieces();
                        permalink.htmlText = '  <font color="#61D2FF"><a target="_blank" href="http://suztomo.net/fp/?url='+targetUrl+'">'
                                + 'Permalink to Pazzle</a></font>';
                        CursorManager.removeBusyCursor();
                }

                private function onBoardComplete(event:FPazzleEvent):void
                {
                        searchbox.enabled = true;
                        board.showPhotoInfo();
                }
                
                private function onNotFound(event:Event):void
                {
                        Alert.show("No photo found by the keyword", "Photo Not Found");
                        searchbox.enabled = true;
                        CursorManager.removeBusyCursor();
                }

                private function onPressKey(event:KeyboardEvent):void
                {
                        if (event.keyCode == 13 && searchbox.enabled) keywordSubmit.dispatchEvent(new MouseEvent(MouseEvent.CLICK));
                }

                private function onSearchFocus():void
                {
                        if (keyword.text == defaultInputText) keyword.text = "";
                }

                private function onSearchLeave():void
                {
                        if (keyword.text.length < 2)
                        keyword.text=defaultInputText;
                }
                

                ]]>
        </mx:Script>


        <mx:Style source="FPazzle.css"/>
</mx:Application>