root/lang/actionscript/FPazzle/trunk/src/net/suztomo/FPazzle/FBoard.as @ 14276

package net.suztomo.FPazzle
{
        import flash.display.*;
        
        import mx.containers.Panel;
        import mx.core.UIComponent;

        public class FBoard extends UIComponent
        {
                public static var pazzleImage:BitmapData;
                [Embed(source='flower.jpg')] private var EmbedImage:Class;

                private var x_num:uint, y_num:uint;
                private var p_width:Number, p_height:Number;
                private static var answerDiff:Number = 2;

                public var pieces:PazzleMap;
                public var keyword:String;
                public var infoPanel:Panel;

                public function FBoard(_x_num:uint, _y_num:uint, _pazzleImage:BitmapData = null)
                {
                        x_num = _x_num;
                        y_num = _y_num;
                        pazzleImage = _pazzleImage;

                        setPazzleImage();

                        p_width = pazzleImage.width / x_num;
                        p_height = pazzleImage.height / y_num;
                        super();
                        
                        pieces = new PazzleMap(x_num, y_num);
                }
                
                public function setPazzleImage() :void
                {
                        if (pazzleImage == null) {
                                var img:Bitmap = new EmbedImage() as Bitmap;
                                pazzleImage = img.bitmapData;
                        }
                }

                public function putPiece(_x:Number = 0, _y:Number = 0, _x_index:uint = 0, _y_index:uint = 0):void
                {
                        var piece:FPiece = new FPiece(pazzleImage, p_width, p_height, _x_index, _y_index);
                        piece.x = _x;
                        piece.y = _y;
                        if (pazzleImage == null) {
                                trace("pazzle Image is not setted");
                        } else {
                                addChild(piece);
                        }
                        
                        pieces.setElement(_x_index, _y_index, piece);
                }
                
                public function createPieces():void
                {
                        var min_x:Number = p_width, min_y:Number = p_height;
                        var range:Number = 400;
                        for (var i:uint=0; i < x_num; i++) {
                                for (var j:uint=0; j < y_num; j++) {
                                        putPiece(min_x + range*Math.random(), min_y + range*Math.random(), j, i);
                                }
                        }
                }

                public function isAnswer():Boolean
                {
                        var tmp1:FPiece, tmp2:FPiece;

                        for (var i:uint = 0; i<y_num; i++) {
                                for (var j:uint = 0; j<x_num; j++) {
                                        tmp1 = pieces.getElement(j, i) as FPiece;
                                        if (tmp1.rotation != 0) return false;
                                        
                                        if (j != x_num-1) {
                                                tmp2 = pieces.getElement(j+1, i) as FPiece;
                                                if (Math.abs(tmp1.x + p_width - tmp2.x) > answerDiff
                                                        || Math.abs(tmp1.y - tmp2.y) > answerDiff){
                                                                return false;
                                                }
                                        }
                                        
                                        if (i != y_num-1) {
                                                tmp2 = pieces.getElement(j, i+1) as FPiece;
                                                if (Math.abs(tmp1.x - tmp2.x) > answerDiff
                                                        || Math.abs(tmp1.y + p_height - tmp2.y) > answerDiff){
                                                        return false;
                                                }
                                        }
                                }
                        }
                        return true;
                }
                
                public function deactivate():void
                {
                        for (var i:uint=0; i<pieces.length; i++) {
                                pieces.getInline(i).deactivate();
                        }
                }
        }
}