root/lang/actionscript/FPazzle/trunk/src/net/suztomo/FPazzle/FBoard.as @ 15005

package net.suztomo.FPazzle
{
        import com.adobe.webapis.flickr.*;
        
        import flash.display.*;
        import flash.events.Event;
        import flash.events.EventDispatcher;
        
        import mx.containers.Panel;
        import mx.controls.*;
        import mx.core.UIComponent;
        
        import net.suztomo.FPazzle.event.*;

        public class FBoard extends UIComponent
        {
                public static var pazzleImage:BitmapData;
//              [Embed(source='flower.jpg')] private var EmbedImage:Class;

                private var x_num:uint, y_num:uint;
                
                private static var answerDiff:Number = 2;
                private var eventDispatcher:EventDispatcher;
                private var numAnsweredPieces:int = 0;;

                public var p_width:Number, p_height:Number;
                public var photo:Photo;
                public var pieces:PazzleMap;
                public var keyword:String;
                public var infoPanel:Panel;
                public var groups:Array;

                public static var BOARD_READY:String = "boardReady";
                public static var BOARD_COMPLETE:String = "boardComplete";
                public static var PIECE_SNAPPED:String = "pieceSnapped";

                public function FBoard(_x_num:uint, _y_num:uint, _pazzleImage:BitmapData = null)
                {
                        x_num = _x_num;
                        y_num = _y_num;
                        pazzleImage = _pazzleImage;

                        eventDispatcher = new EventDispatcher();

                        groups = new Array();

                        p_width = Math.floor(pazzleImage.width / x_num);
                        p_height = Math.floor(pazzleImage.height / y_num);
                        
                        pieces = new PazzleMap(x_num, y_num);
                        super();
                }
                                
                public function setPazzleImage(p:Photo) :void
                {
                        photo = p;
                }

                public function putPiece(_x:Number = 0, _y:Number = 0, _x_index:uint = 0, _y_index:uint = 0):void
                {
                        var piece:FPiece = new FPiece(pazzleImage, p_width, p_height, _x_index, _y_index);
                        if (pazzleImage == null) {
                                trace("pazzle Image is not setted");
                        } else {
                                putPieceGroup(piece,_x, _y);
                        }

                        pieces.setElement(_x_index, _y_index, piece);
                }
                
                public function putPieceGroup(p:FPiece, _x:Number = 0, _y:Number = 0):void
                {
                        var pg:FPieceGroup = new FPieceGroup(p);
                        pg.x = p.parent ? p.parent.x : _x;
                        pg.y = p.parent ? p.parent.y : _y;
                        addChild(pg);
                        groups.push(pg);
                }
                
                public function createPieces():void
                {
                        var min_x:Number = p_width + 160, min_y:Number = 100;
                        var range_x:Number = 600;
                        var range_y:Number = 400;
                        for (var i:uint=0; i < x_num; i++) {
                                for (var j:uint=0; j < y_num; j++) {
                                        putPiece(min_x + range_x*Math.random(), min_y + range_y*Math.random(), j, i);
                                }
                        }
                }

                public function checkAnswer():void
                {
                        if (isAnswer()) {
                                deactivate();
                                dispatchEvent(new FPazzleEvent(FBoard.BOARD_COMPLETE));
                        }
                }

                public function isAnswer():Boolean
                {
                        var tmp1:FPiece, tmp2:FPiece;
                        var g:FPieceGroup = pieces.getElement(0, 0).group;
                        for (var i:uint = 0; i<y_num; i++) {
                                for (var j:uint = 0; j<x_num; j++) {
                                        tmp1 = pieces.getElement(j, i) as FPiece;
                                        if (tmp1.rotation != 0) return false;
                                        if (tmp1.group != g) return false;
                                        
                                        if (j != x_num-1) {
                                                tmp2 = pieces.getElement(j+1, i) as FPiece;
                                                if (Math.abs(tmp1.x + p_width - tmp2.x) > answerDiff
                                                        || Math.abs(tmp1.y - tmp2.y) > answerDiff){
                                                        return false;
                                                }
                                        }
                                        
                                        if (i != y_num-1) {
                                                tmp2 = pieces.getElement(j, i+1) as FPiece;
                                                if (Math.abs(tmp1.x - tmp2.x) > answerDiff
                                                        || Math.abs(tmp1.y + p_height - tmp2.y) > answerDiff){
                                                        return false;
                                                }
                                        }
                                }
                        }
                        return true;
                }
                
                public function showPhotoInfo():void
                {
                        var str:String = "";
                        var p:Photo = photo;
                        if (p != null) {
                                if (p.title)
                                        str += "Title: " + p.title + "\n";
                                if (p.description)
                                        str += p.description + "\n";
                                if (p.tags && p.tags.length > 0)
                                        str += "Tags: " + p.tags.toString() + "\n";
                                if (p.dateTaken)
                                        str += "Taken Date: " + p.dateTaken.fullYear + "/" + (p.dateTaken.month+1) + "/" + p.dateTaken.day + "\n\n";
/*                              if (p.url)
                                        str += "URL: " + p.url + "\n";
                                if (p.id)
                                        str += "ID: " + p.id + "\n";*/
        
                                if (p.ownerName)
                                        str += "Owner: " + p.ownerName + ((p.ownerRealName != null) ? ("(" + p.ownerRealName + ")") : "") + "\n";
                                if (p.ownerLocation)
                                str += "Location: " + p.ownerLocation + "\n";
                        }

                        Alert.show(str, "Completed");
                }
                
                public function deactivate():void
                {
                        for (var i:uint=0; i<pieces.length; i++) {
                                pieces.getInline(i).deactivate();
                        }
                        
                        for (i=0; i<groups.length; i++) {
                                (groups[i] as FPieceGroup).deactivate();
                        }
                }
                
                public function traceGroupId():void
                {
                        trace("------traceGroupId()-----");
                        for each(var g:FPieceGroup in groups){
                                g.traceId();
                        }
                }
                
                public function showAnswer():void
                {
                        var g:FPieceGroup = groups[0];
                        g.x = p_width*x_num * 0.4 + 300;
                        g.y = 150;
                        
                        for (var j:uint=0; j<groups.length;j++) {
                                (groups[j] as FPieceGroup).deactivate();
                        }
                        
                        for (var i:uint=0; i<pieces.length; i++) {
                                g.putNewPiece(pieces.getInline(i) as FPiece);
                        }
                        
                        slideNextPiece();
                }
                
                public function slideNextPiece():void
                {
                        if (numAnsweredPieces >= pieces.length) {
                                checkAnswer();
                                return;
                        }

                        var p:FPiece = pieces.getInline(numAnsweredPieces) as FPiece;
                        p.slideTo((numAnsweredPieces % x_num) * p_width, Math.floor(numAnsweredPieces / x_num) * p_height);
                        numAnsweredPieces += 1;
                }
                
                // Event Listeners
                public override function addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void
                {
                        eventDispatcher.addEventListener(type, listener, useCapture, priority, useWeakReference);
                }
                
                public override function removeEventListener(type:String, listener:Function, useCapture:Boolean=false):void
                {
                        eventDispatcher.removeEventListener(type, listener, useCapture);
                }
                
                public override function hasEventListener(type:String):Boolean
                {
                        return eventDispatcher.hasEventListener(type);
                }
                
                public override function willTrigger(type:String):Boolean
                {
                        return eventDispatcher.willTrigger(type);
                }
                
                public override function dispatchEvent(event:Event):Boolean
                {
                        return eventDispatcher.dispatchEvent(event);
                }
        }
}