root/lang/actionscript/FPazzle/trunk/src/net/suztomo/FPazzle/FPieceGroup.as @ 14406

package net.suztomo.FPazzle
{
        import flash.display.Sprite;
        import flash.events.Event;
        import flash.events.MouseEvent;
        
        import net.suztomo.FPazzle.event.*;

        public class FPieceGroup extends Sprite
        {
                private static var snapDistance:Number = 20;
                private var p_width:Number, p_height:Number;
                private var init_piece:FPiece;
                
                public var pieces:Array;
                public var handle:Sprite;
                public var board:FBoard;
                
                public function FPieceGroup(p:FPiece)
                {
                        super();
                        pieces = new Array();
                        pieces.push(p);
                        init_piece = p;
                        addEventListener(Event.ADDED, onAdded);
                        
                        handle = new Sprite;
                        handle.graphics.beginFill(0x222222, 1);
                        handle.graphics.drawCircle(0, 0, 30);
                        handle.alpha = 0.0;
                        addChild(handle);
                        initHandleListener();
                }

                public function onAdded(e:Event):void
                {
                        if (e.target == this) {
                                board = parent as FBoard;
                                for (var i:uint=0; i<pieces.length; i++) {
                                        addChildAt(pieces[i], 0);
                                }
                                p_width = board.p_width;
                                p_height = board.p_height;
                        }
                }

                public function putNewPiece(p:FPiece):void
                {
                        if (p == pieces[0]) return;
                        pieces.push(p);
                        if (p.parent) {
                                if (pieces.length == 1) {
                                        x = p.parent.x + p.x;
                                        y = p.parent.y + p.y;
                                        p.x = 0;
                                        p.y = 0;
                                } else {
                                        p.x = p.parent.x - x + p.x;
                                        p.y = p.parent.y - y + p.y;
                                }
                        }
                        for(var i:uint=0; i<pieces.length; i++) {
                                addChildAt(pieces[i], 0);
                        }
                        setHandlePosition();
                }

                private function initHandleListener():void
                {
                        handle.addEventListener(MouseEvent.MOUSE_OVER, handleAppear);
                        handle.addEventListener(MouseEvent.MOUSE_OUT, handleDisappear);
                        handle.addEventListener(MouseEvent.MOUSE_DOWN, startDragGroup);
                        handle.addEventListener(MouseEvent.MOUSE_UP, stopDragGroup);
                }
                
                private function setHandlePosition():void
                {
                        var offset_x:Number = 0;
                        var offset_y:Number = 0;
                        var handle_x:Number=0, handle_y:Number=0;

                        if (pieces.length < 1) {
                                alpha = 0.3;
                                return;
                        } else {
                                alpha = 1;
                        }

                        for (var i:uint; i<pieces.length; i++) {
                                handle_x += pieces[i].x;
                                handle_y += pieces[i].y;
                        }
                        handle.x = handle_x / pieces.length + offset_x;
                        handle.y = handle_y / pieces.length + offset_y;
                }
                
                public function removePiece(p:FPiece):void
                {
                        if (p == init_piece && pieces.length > 1) {
                                var new_p:FPiece = init_piece;
                                var i:uint;
                                for (i=0; new_p == init_piece; i++) {
                                        new_p = pieces[i];
                                }
                                var movePiece:FPiece;
                                while((movePiece = pieces.pop() as FPiece) != null) {
                                        if (movePiece != init_piece) {
                                                new_p.init_group.putNewPiece(movePiece);
                                        }
                                }
                                pieces.push(init_piece);
                        } else {
                                pieces.splice(pieces.indexOf(p, 0), 1);
                        }
                        setHandlePosition();
                }
                
                private function handleAppear(e:Event):void
                {
                        if (pieces.length > 1) handle.alpha = 1;
                        e.stopPropagation();
                }
                
                private function handleDisappear(e:Event):void
                {
                        handle.alpha = 0.0;
                        e.stopPropagation();
                }
                
                public function startDragGroup(e:Event):void
                {
                        startDrag();
                        e.stopPropagation();
                }
                
                public function stopDragGroup(e:Event):void
                {
                        stopDrag();
                        snap();
                        board.checkAnswer();
                        e.stopPropagation();
                }

                private function snap():void
                {
                        var i:int;
                        var tmp:FPieceGroup;
                        var orig_x:Number = x;
                        var orig_y:Number = y;

                        var offset_x:Number, offset_y:Number;

                        var diff_x:Number;
                        var diff_y:Number;
                        var x_snap:Number, y_snap:Number;
                        var snap_to:FPieceGroup = null;
                        var snapped_x:Boolean = false, snapped_y:Boolean = false;
                        var min_dist:Number = snapDistance*snapDistance*2, tmp_dist_x:Number, tmp_dist_y:Number;

                        for (i=0; i<board.pieces.length; i++) {
                                tmp = board.groups[i] as FPieceGroup;
                                x_snap = 0;
                                y_snap = 0;
                                
                                if (tmp != this && tmp.pieces.length > 0) {
                                        snapped_x = false;
                                        snapped_y = false;
                                        for (var j:int=-1; j<=1; j++) {
                                                diff_x = tmp.x + p_width * j - orig_x;
                                                diff_y = tmp.y + p_height * j - orig_y;
                                                if (Math.abs(diff_x) < snapDistance) {
                                                        x_snap = tmp.x + p_width*j;
                                                        snapped_x = true;
                                                        tmp_dist_x = diff_x*diff_x;
                                                }
                                                if (Math.abs(diff_y) < snapDistance) {
                                                        y_snap = tmp.y + p_height*j;
                                                        snapped_y = true;
                                                        tmp_dist_y = diff_y*diff_y;
                                                }
                                        }
                                        
                                        if (snapped_x && snapped_y && min_dist > (tmp_dist_x + tmp_dist_y)) {
                                                x = x_snap;
                                                y = y_snap;
                                                snap_to = tmp;
                                                min_dist = tmp_dist_x + tmp_dist_y;
                                        }
                                }
                        }

                        if (snap_to != null) {
                                var movePiece:FPiece;
                                for (i=pieces.length-1; i>= 0; i--) {
                                        movePiece = pieces[i];
                                        removePiece(movePiece);
                                        snap_to.putNewPiece(movePiece);
                                }
                                board.dispatchEvent(new FPazzleEvent(FBoard.PIECE_SNAPPED));
                        }
                }
                
                public function deactivate():void
                {
                        handle.removeEventListener(MouseEvent.MOUSE_OVER, handleAppear);
                        handle.removeEventListener(MouseEvent.MOUSE_OUT, handleDisappear);
                        handle.removeEventListener(MouseEvent.MOUSE_DOWN, startDragGroup);
                        handle.removeEventListener(MouseEvent.MOUSE_UP, stopDragGroup);
                }
        }
}