root/lang/actionscript/ascss/src/CSSTest.as @ 9972

package
{
        import flash.display.*;
        import flash.text.*;
        import flash.events.*;
        import css.*;
        import ascsstest.*;
        public class CSSTest extends Sprite
        {
                public static var theInstance:CSSTest;
                private var mTextOut:TextField;
                private var mCSS:ASCSS;
                private var mVLayer:Sprite;
                private var mELayer:Sprite;

                private var mPrevX:int;
                private var mPrevY:int;

                public static const T_CSS:String = 
"@charset \"euc-jp\";\n\n/* AMAZON */\n\ndiv.hatena-asin-recommend {\n  margin: 4px 10px 4px 10px;\n    padding: 5px 4px;\n     width: 96%;\n   text-align: left;\n}\n\ndiv.hatena-asin-recommend a {\n text-decoration: none;\n        border: none;\n}\n\ndiv.hatena-asin-recommend-item-1 {\n        float: left;\n  width: 49%;\n}\n\ndiv.hatena-asin-recommend-item-2 {\n  float: right;\n width: 49%;\n}\n\ndiv.hatena-asin-recommend-foot {\n    clear: both;\n}\n\ndiv.hatena-asin-recommend-image {\n  float: left;\n}\n\ndiv.hatena-asin-recommend-image img {\n      border: none;\n}\n\ndiv.hatena-asin-recommend-info {\n  margin-left: 65px;\n    min-height: 65px;\n     line-height: 115%;\n}\n\ndiv.hatena-asin-recommend-title {\n    margin-left: 24px;\n    font-size: 11px;\n      font-weight: bold;\n}";

                function CSSTest()
                {
                        stage.scaleMode = StageScaleMode.NO_SCALE;

                        var g:Graphics = graphics;

                        mELayer = new Sprite();
                        addChild(mELayer);

                        mVLayer = new Sprite();
                        addChild(mVLayer);

                        mTextOut = new TextField();
                        mTextOut.width  = 600;
                        mTextOut.height = 800;
                        mTextOut.x = 8;
                        mTextOut.y = 8;
                        mTextOut.textColor = 0xffffff;
                        mTextOut.mouseEnabled = false;
                        addChild(mTextOut);
                        theInstance = this;
puts(T_CSS);
                        var pex:PropExt = new PropExt();
                        mCSS = new ASCSS(T_CSS, CSSTest);
                        mCSS.propertyExtension = pex;
                        mCSS.parse();

                        var sheet:StyleList = mCSS.sheet;
                        var sv:StyleListVisual = new StyleListVisual(sheet);
                        sv.edgeLayer = mELayer;
                        mVLayer.addChild(sv);

                        sv.x = 10;
                        sv.y = 10;

                        generateStyleListChildren(sheet, sv);

                        sv.calcSize(false);
                        sv.calcMaxWidth();
                        sv.locate();
                        mELayer.graphics.clear();
                        sv.renderEdge(mELayer, 0xffffff);

                        stage.addEventListener(MouseEvent.MOUSE_DOWN, onMouseDown);
                        stage.addEventListener(MouseEvent.MOUSE_MOVE, onMouseMove);
                }

                private function onMouseDown(e:MouseEvent):void
                {
                        mPrevX = stage.mouseX;
                        mPrevY = stage.mouseY;
                }

                private function onMouseMove(e:MouseEvent):void
                {
                        if (e.buttonDown)
                        {
                                var dx:int = stage.mouseX - mPrevX;
                                var dy:int = stage.mouseY - mPrevY;

                                if (mELayer != null && mVLayer != null && (dx != 0 || dy != 0))
                                {
                                        mELayer.x += dx;
                                        mELayer.y += dy;

                                        mVLayer.x += dx;
                                        mVLayer.y += dy;

                                        mTextOut.y = 8 + mVLayer.y/9;

                                        e.updateAfterEvent();
                                }

                                mPrevX = stage.mouseX;
                                mPrevY = stage.mouseY;
                        }
                }

                private function generateStyleListChildren(sl:StyleList, sv:StyleListVisual):void
                {
                        var ch:StyleBase;
                        var len:uint = sl.length;
                        var children:Array = [];

                        for (var i:uint = 0;i < len;i++)
                        {
                                ch = sl.item(i);

                                if (ch is CSSRule)
                                {
                                        var v:RuleVisual = new RuleVisual(CSSRule(ch));
                                        mVLayer.addChild(v);

                                        if (ch is CSSStyleRule)
                                                generateStyleRuleChildren(CSSStyleRule(ch), v);

                                        children.push(v);
                                }
                        }

                        chain(sv, children);
                }

                private function generateStyleRuleChildren(sr:CSSStyleRule, sv:RuleVisual):void
                {
                        var v:SelectorVisual;
                        var nx:CSSSelector = sr.selector;
                        var children:Array = [];

                        while(nx != null)
                        {
                                v = new SelectorVisual(nx);
                                mVLayer.addChild(v);
                                children.push(v);

                                generateSelectorChildren(nx, v);

                                nx = nx.next;
                        }

                        if (sr.declaration != null)
                        {
                                var dv:DeclarationVisual = new DeclarationVisual(sr.declaration);
                                mVLayer.addChild(dv);
                                children.push(dv);

                                if (sr.declaration is CSSMutableStyleDeclaration)
                                        generateMutableDeclarationChildren(CSSMutableStyleDeclaration(sr.declaration), dv);
                        }

                        chain(sv, children);
                }


                private function generateSelectorChildren(ss:CSSSelector, sv:SelectorVisual):void
                {
                        if (ss.mTagHistory != null)
                        {
                                var v:SelectorVisual = new SelectorVisual(ss.mTagHistory);
                                mVLayer.addChild(v);
                                sv.firstChild = v;
                        }
                }

                private function generateMutableDeclarationChildren(sd:CSSMutableStyleDeclaration, sv:DeclarationVisual):void
                {
                        var len:uint = sd.length;
                        var children:Array = [];
                        for (var i:uint;i < len;i++)
                        {
                                var v:PropertyVisual = new PropertyVisual(sd.rawItem(i));
                                mVLayer.addChild(v);
                                children.push(v);

                                generatePropertyChildren(sd.rawItem(i), v);
                        }

                        chain(sv, children);
                }

                private function generatePropertyChildren(cp:CSSProperty, pv:PropertyVisual):void
                {
                        var val:CSSValue = cp.value;
                        if (val == null)
                                return;

                        var v:ValueVisual = new ValueVisual(val);

                        if (val is CSSValueList)
                                generateValueListChildren(CSSValueList(val), v);

                        mVLayer.addChild(v);
                        pv.firstChild = v;
                }

                private function generateValueListChildren(cv:CSSValueList, vv:ValueVisual):void
                {
                        var len:uint = cv.length;
                        var children:Array = [];
                        for (var i:uint;i < len;i++)
                        {
                                var v:ValueVisual = new ValueVisual(cv.item(i));
                                mVLayer.addChild(v);
                                children.push(v);
                        }

                        chain(vv, children);
                }

                private function chain(parent:StyleVisualBase, children:Array /* of StyleVisualBase */):void
                {
                        var prev:StyleVisualBase = null;
                        for each(var ch:StyleVisualBase in children)
                        {
                                if (prev == null)
                                        parent.firstChild = ch;
                                else
                                        prev.nextSibling = ch;

                                prev = ch;
                        }
                }

                public static function puts(msg:*):void
                {
                        if (theInstance != null)
                                theInstance.mTextOut.appendText(msg.toString() + "\n");
                }
        }
}

class PropExt implements css.IPropertyExtension
{
        import css.*;

        private var mAzimuthPropID:int;
        function PropExt()
        {
                mAzimuthPropID = CSSPropertyID.addExtProp("azimuth");
        }

        public function isValidPrimitiveValue(aPropID:int, aValueId:int):Boolean
        {
                if (aPropID == mAzimuthPropID)
                {
                        return true;
                }

                return false;
        }
}