root/lang/actionscript/colorpicker/kugyu/ColorCircle.as @ 7708

package kugyu
{
        import flash.display.*;
        import flash.geom.*;
        public class ColorCircle extends Sprite
        {
                public static const radToDeg:Number = 180.0/Math.PI;
                
                private var mImg:Bitmap;
                private var mImgData:BitmapData;
                private var mCursor:Sprite;
                
                private var mH:Number;
                private var mS:Number;
                private var mV:Number;
                private var mCenter:int;
                
                private var mColorTrans:ColorTransform = new ColorTransform();

                function ColorCircle(R:int)
                {
                        mCenter = R;
                        mV = 1;
                        
                        addChild(
                                generateColors(graphics, R*2)
                        );
                        
                        addChild(mCursor = createBorder(R));
                        addChild(mCursor = createCursor());
                        
                        setHSV(0, 0, 1);
                }
                
                private function createBorder(R:int):Sprite
                {
                        var s:Sprite = new Sprite();
                        var g:Graphics = s.graphics;
                        
                        g.lineStyle(3, 0xffffff, 1, true);
                        g.drawCircle(R, R, R);
                        g.endFill();
                        
                        return s;
                }
                
                public function setCenterPos(ax:int, ay:int):void
                {
                        x = ax - mCenter;
                        y = ay - mCenter;
                }
                
                private function createCursor():Sprite
                {
                        var s:Sprite = new Sprite();
                        var g:Graphics = s.graphics;

                        g.lineStyle(3, 0xffffff, 1, true);
                        g.drawCircle(0, 0, 5);

                        g.lineStyle(1, 0x000000, 1, true);
                        g.drawCircle(0, 0, 5);
                        
                        return s;
                }
                
                public function setHSV(H:Number, S:Number, V:Number):void
                {
                        if (S<0) S=0;
                        if (S>1) S=1;
                        
                        mH = H;
                        mS = S;
                        mV = V;
                        
                        updateCursor();
                }
                
                public function updateCursor():void
                {
                        var x:Number = int(Math.cos(mH) * mS * Number(mCenter));
                        var y:Number = int(Math.sin(mH) * mS * Number(mCenter));
                        
                        mCursor.x = x + mCenter;
                        mCursor.y = y + mCenter;
                        
                        
                        mColorTrans.redMultiplier = mV;
                        mColorTrans.greenMultiplier = mV;
                        mColorTrans.blueMultiplier = mV;
                        mImg.transform.colorTransform = mColorTrans;
                }
                
                public function setByMousePos():void
                {
                        var x:Number = mouseX - mCenter;
                        var y:Number = mouseY - mCenter;
                        
                        var S:Number = Math.sqrt(x*x + y*y) / Number(mCenter);
                        var H:Number = Math.atan2(y, x);
                        setHSV(H, S, mV);
                }
                
                public function get rgb():uint
                {
                        return ColorConv.HSVtoRGB(mH*radToDeg, mS, mV);
                }

                public function get base_rgb():uint
                {
                        return ColorConv.HSVtoRGB(mH*radToDeg, mS, 1);
                }
                
                public function get H():Number
                {
                        return mH;
                }

                public function get S():Number
                {
                        return mS;
                }

                public function set V(v:Number):void
                {
                        if (v != mV)
                        {
                                mV = v;
                                updateCursor();
                        }
                }
                
                private function generateColors(g:Graphics, size:int):Bitmap
                {
                        mImgData = new BitmapData(size, size, true, 0);
                        mImg = new Bitmap(mImgData);
                        
                        var x:int;
                        var y:int;
                        var center:int = mCenter;
                        
                        for (y = 0;y < size;y++)
                        {
                                for (x = 0;x < size;x++)
                                {
                                        var dx:Number = Number(x-center);
                                        var dy:Number = Number(y-center);
                                        
                                        var S:Number = Math.sqrt(dx*dx + dy*dy) / Number(center);
                                        var H:Number = Math.atan2(dy, dx);
                                        
                                        var alpha:Number = 80.0 - S*80.0;
                                        if (alpha<0) continue;
                                        if (alpha>1) alpha = 1;
                                        
                                        
                                        mImgData.setPixel32(x, y, (uint(alpha*255)<<24)|ColorConv.HSVtoRGB(H*radToDeg, S, mV));
                                }
                        }
                        
                        
                        
                        return mImg;
                }
        }
}