root/lang/actionscript/flmml/trunk/src/com/txt_nifty/sketch/flmml/MOscSine.as @ 27528

package com.txt_nifty.sketch.flmml {
    import __AS3__.vec.Vector;

    public class MOscSine extends MOscMod {
        protected static var s_init:int = 0;
        protected static var s_table:Vector.<Number> = new Vector.<Number>(TABLE_LEN, true);

        public function MOscSine() {
            boot();
            super();
        }
        public static function boot():void {
            if (s_init) return;
            var d0:Number = 2.0 * Math.PI / TABLE_LEN;
            var p0:Number;
            var i:int;
            for(i = 0, p0 = 0.0; i < TABLE_LEN; i++) {
                s_table[i] = Math.sin(p0);
                p0 += d0;
            }
            s_init = 1;
        }
        public override function getNextSample():Number {
            var val:Number = s_table[m_phase >> PHASE_SFT];
            m_phase = (m_phase + m_freqShift) & PHASE_MSK;
            return val;
        }
        public override function getNextSampleOfs(ofs:int):Number {
            var val:Number = s_table[((m_phase + ofs) & PHASE_MSK) >> PHASE_SFT];
            m_phase = (m_phase + m_freqShift) & PHASE_MSK;
            return val;
        }
        public override function getSamples(samples:Vector.<Number>, start:int, end:int):void {
            var i:int;
            for(i = start; i < end; i++) {
                samples[i] = s_table[m_phase >> PHASE_SFT];
                m_phase = (m_phase + m_freqShift) & PHASE_MSK;
            }
        }
    }
}