root/lang/actionscript/gmapkmz/ConfirmBox.as

package
{
        import flash.display.*;
        import flash.text.*;
        import flash.events.*;
        public class ConfirmBox extends Sprite
        {
                private var mYesButton:CButton;
                private var mNoButton:CButton;

                private var mCText:TextField = new TextField();
                private var mYText:TextField = new TextField();
                private var mNText:TextField = new TextField();
                function ConfirmBox(ctext:String, onYes:Function, onNo:Function)
                {
                        var fmt:TextFormat = new TextFormat();
                        fmt.font = "Arial";
                        fmt.size = 16;
                        
                        mCText.defaultTextFormat = fmt;
                        mYText.defaultTextFormat = fmt;
                        mNText.defaultTextFormat = fmt;
                        mCText.text = ctext;
                        mNText.text = "No";
                        mYText.text = "Yes";
                        mCText.mouseEnabled = false;
                        mNText.mouseEnabled = false;
                        mYText.mouseEnabled = false;

                        mCText.width = mCText.textWidth + 8;
                        mYText.x = mCText.textWidth + 16;
                        mNText.x = mYText.x + mYText.textWidth + 16;

                        addChild(mCText);

                        drawBase(graphics);

                        mYesButton = new CButton(mYText.textWidth + 5, mYText.textHeight + 4);
                        mYesButton.x = mYText.x - 1;
                        mYesButton.y = mYText.y - 1;
                        addChild(mYesButton);
                        mYesButton.buttonMode = true;
                        mYesButton.addEventListener(MouseEvent.CLICK, onYes);

                        mNoButton = new CButton(mNText.textWidth + 5, mNText.textHeight + 4);
                        mNoButton.x = mNText.x - 1;
                        mNoButton.y = mNText.y - 1;
                        addChild(mNoButton);
                        mNoButton.buttonMode = true;
                        mNoButton.addEventListener(MouseEvent.CLICK, onNo);

                        addChild(mNText);
                        addChild(mYText);
                }

                protected function drawBase(g:Graphics):void
                {
                        g.beginFill(0xffffff, 0.8);
                        g.lineStyle(3, 0xffffff, 0.2);
                        g.drawRect(-4, -4, mNText.x + mNText.textWidth + 20, mCText.textHeight + 10);
                }
        }
}

class CButton extends flash.display.Sprite
{
        import flash.geom.*;
        import flash.display.*;

        public static const GRAD_COLORS:Array = [0xcccccc, 0xffffff, 0xeeeeee, 0xcccccc, 0xbbbbbb];
        public static const GRAD_ALPHAS:Array = [1,        1,        1,        1,        1       ];
        public static const GRAD_RATIOS:Array = [0,        5,        120,      121,      255     ];
        private var mGradTrans:Matrix = new Matrix();

        function CButton(w:int, h:int)
        {
                mGradTrans.createGradientBox(h, h, Math.PI/2, 0, 0);

                var g:Graphics = graphics;
                g.beginGradientFill(GradientType.LINEAR, GRAD_COLORS, GRAD_ALPHAS, GRAD_RATIOS, mGradTrans);
                g.lineStyle(0, 0, 0.2);
                g.drawRect(0, 0, w, h);
        }
}