root/lang/actionscript/hatesuta/src/Hatesuta.as @ 112

package {
    import flash.display.Sprite;
    import hatesuta.*;
    import flash.display.StageAlign;
    import flash.display.StageScaleMode;
    import com.rails2u.utils.ColorUtil;
    import com.rails2u.utils.MathUtil;
    import flash.events.TimerEvent;
    import flash.utils.Timer;
    import com.rails2u.swflayer.SWFLayer;
    import com.rails2u.net.JSONPLoader;
    import caurina.transitions.Tweener;
    import flash.display.MovieClip;
    import flash.net.URLRequest;
    import flash.display.Loader;
    import flash.events.Event;
    import flash.display.DisplayObject;
    import sketchbook.colors.ColorSB;
    import flash.display.StageQuality;
    import flash.net.URLLoader;
    import flash.events.MouseEvent;
    import com.rails2u.net.navigateToURL;
    import flash.text.TextField;
    import flash.external.ExternalInterface;
    import flash.system.Security;
    import flash.events.IOErrorEvent;
    import flash.errors.IOError;

    [SWF(frameRate=60, background=0xFFFFFF)]
    public class Hatesuta extends Sprite {
        public var swf:SWFLayer;
        public var fallingTimer:Timer;
        public var fallingContainer:Sprite;
        public var bs:BigStar;

        public function Hatesuta() {
            stage.align = StageAlign.TOP_LEFT;
            stage.scaleMode = StageScaleMode.NO_SCALE;

            Security.allowDomain('*');
            run();
        }

        public function run():void {
            swf = SWFLayer.getInstance();
            // swf.fitInBrowser();

            bs = new BigStar();
            jsonpLoad();
            runFallingStars();
        }

        private function jsonpLoad():void {
            var url:String = SWFLayer.execExternalInterface('return window.location.href;');
            var hatenaRegex:RegExp = new RegExp('^(https?://[^/]*?((\.g)|b|d)\.hatena\.ne\.jp/[^/]*)(.*)');
            if (url.match(hatenaRegex)) {
                url = url.replace(hatenaRegex, "$1/").replace(/\/\/$/, '/');
            }
            var loader:JSONPLoader = new JSONPLoader('http://s.hatena.ne.jp/blog.json/' + url);
            loader.addEventListener(IOErrorEvent.IO_ERROR, function(e:Event):void {
                // log(e.target.url);
            });
            loader.addEventListener(Event.COMPLETE, jsonpCompleteHandler);
            loader.load();
        }

        private function runFallingStars():void {
            fallingContainer = new Sprite();
            fallingContainer.graphics.beginFill(0xDDDDDD, 0);
            fallingContainer.graphics.drawRect(0,0,stage.stageWidth, stage.stageHeight);
            fallingContainer.graphics.endFill();
            addChild(fallingContainer);

            var fs:FirstFallingStars = new FirstFallingStars(stage.stageWidth * 2/5,stage.stageHeight  + 50, 5, 0xFFAC66, 15);
            fs.createStars();
            fallingContainer.addChild(fs);

            fallingTimer = new Timer(100);
            fallingTimer.addEventListener(TimerEvent.TIMER, fallingTimerHandler);
            fallingTimer.start();
        }

        private function fallingTimerHandler(e:TimerEvent):void {
            var c:int = Math.min(e.target.currentCount, 20);
            var fs:FallingStars;
            var csb:ColorSB = new ColorSB(ColorUtil.random(128,128,128));

            for (var i:uint = 0; i < 20 - Math.min(c, 10); i++) {
                if (e.target.currentCount == 1) {
                    fs = new FirstFallingStars(stage.stageWidth * (1.5/5 + Math.random() / 5),stage.stageHeight + 50,
                            MathUtil.randomBetween(3 * c,5 * c), 
                            ColorUtil.random(255,128,66),
                            10);
                    fs.delay = true;
                } else {
                    csb.hue += 5;
                    csb.saturation += 5;
                    csb.brightness += 5;
                    fs = new FallingStars(MathUtil.randomBetween(-stage.stageWidth,stage.stageWidth),
                            MathUtil.randomBetween(stage.stageHeight + 100 ,stage.stageHeight + 500), 
                            MathUtil.randomBetween(3 * c,5 * c), 
                            csb.value,
                            Math.max(8 - c, 3));
                }
                fs.createStars();
                fallingContainer.addChild(fs);
            }

            if (e.target.currentCount == 25) {
                runBigStar();
            }

            if (e.target.currentCount == 30) {
                var origQuality:String = stage.quality;
                stage.quality = StageQuality.LOW;
                Tweener.addTween(fallingContainer, {
                    alpha:0,
                    transition: 'linear',
                    onCompleteParams: [origQuality],
                    onComplete: stopFalling,
                    time:0.7
                });
            }
        }

        private function runBigStar():void {
            addChild(bs);
            bs.addEventListener(Event.COMPLETE, function(e:Event):void {
                runFont();
            });
            bs.move();
        }

        private function runFont():void {
            for each(var fName:String in ['ha', 'te', 'su', 'ta']) {
                var font:Font = new Font(fName);
                if (fName == 'ha') 
                    font.addEventListener(Event.COMPLETE, fontCompleteHandler);
                addChild(font);
                font.move();
            }
        }

        private var runFinish:Boolean = false;
        private function fontCompleteHandler(e:Event):void {
            runFinish = true;
            stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler);

            if (jsonpData) starCountView();
        }

        private function mouseDownHandler(e:MouseEvent):void {
            swf.style.display = 'none';
        }

        private function stopFalling(origQuality:String):void {
            stage.quality = origQuality;
            fallingTimer.stop();
            removeChild(fallingContainer);
        }

        private var jsonpData:Object;
        private function jsonpCompleteHandler(e:Event):void {
            this.jsonpData = e.target.data;
            if (runFinish) starCountView();
        }

        private function starCountView():void {
            var cv:Sprite = new Sprite;

            var count:String = String(jsonpData['star_count']);
            var sWidth:uint = count.length * 14 + 73;
            cv.graphics.beginFill(0x555555, 0.8);
            cv.graphics.drawRoundRectComplex(0,0, sWidth, 50, 10,10,10,10);
            cv.graphics.endFill();
            addChild(cv);
            cv.y = stage.stageHeight - 60;
            cv.x = stage.stageWidth + sWidth + 10;
            var st:MovieClip = new (BigStar.starSWF);
            st.scaleX = 0.5;
            st.scaleY = 0.5;
            cv.addChild(st);
            st.x = 8;
            st.y = 7;
            var t:TextField = new TextField;
            t.width = 800;
            t.htmlText = '<font size="30" face="arial" color="#FED924">' + count + '</font>';
            t.x = 43;
            t.y = 7;
            cv.addChild(t);
            cv.addEventListener(MouseEvent.MOUSE_DOWN, function(e:MouseEvent):void {
                 e.stopPropagation();
                 com.rails2u.net.navigateToURL(new URLRequest('http://s.hatena.ne.jp/'), '_blank');
            });
            Tweener.addTween(cv, {
                x: stage.stageWidth - sWidth - 10,
                time:1
            });
        }
    }
}