root/lang/actionscript/hatesuta/src/hatesuta/FallingStars.as @ 111

package hatesuta {
    import flash.display.Sprite;
    import flash.events.Event;
    import sketchbook.colors.ColorSB;
    import flash.geom.Point;
    import caurina.transitions.Tweener;
    import flash.utils.setTimeout;
    import flash.filters.DropShadowFilter;
    public class FallingStars extends Sprite {
        public var size:Number;
        public var color:uint;
        public var length:uint;
        public var delay:Boolean = true;

        public var stars:Array = [];
        public function FallingStars(x:Number, y:Number, size:Number, color:uint, length:uint) {
            this.x = x;
            this.y = y;
            this.size = size;
            this.color = color;
            this.length = length;
        }

        public function createStars():void {
            var csb:ColorSB = new ColorSB(color);
            var star:Star;
            for (var i:uint = 0; i < length; i++) {
                star = new Star();
                star.rotation = Math.random() * 50;
                var iSize:Number = size * (1 + i * 0.25);
                var margin:Number = i * (iSize * 2.5);
                star.x = -margin;
                star.y = margin;
                star.drawStar(csb.value, iSize);
                colorRotate(csb);
                stars.push(star);
                addChild(star);
            }
            var p:Point = star.localToGlobal(new Point(star.x , star.y));
            var self:FallingStars = this;
            var delayTime:uint = 0;
            if (delay) {
                delayTime = Math.random() * 200;
            }

            setTimeout(function():void {
                Tweener.addTween(self, {
                    x: x + p.y + (Math.random() * 500 - 250),
                    y: y - p.y - 200,
                    transition: 'easeInSine',
                    time:3
                });
            }, delayTime);
            self.addEventListener(Event.ENTER_FRAME, enterFrameHandler);
        }

        public function colorRotate(csb:ColorSB):void {
            csb.hue += 15;
            csb.saturation += 15;
            // csb.brightness += 5;
        }

        public static var zeroPoint:Point = new Point(0, 0);
        private function enterFrameHandler(e:Event):void {
            //x += size;
            //y -= size;
            var star:Star;
            for (var i:uint = 0; i < stars.length; i++) {
                star = stars[i];
                star.rotation += 10;
            }
            if(star.localToGlobal(FallingStars.zeroPoint).y < -(star.height / 2)) {
                destroy();
            }
        }

        public function destroy():void {
            parent.removeChild(this);
            removeEventListener(Event.ENTER_FRAME, enterFrameHandler);
        }

        public function fail():void {
        }
    }
}