root/lang/actionscript/metro-map/Viewer.as @ 7021

package
{
        import flash.display.*;
        import flash.text.*;
        import flash.events.*;
        import flash.net.URLRequest;
        import flash.geom.ColorTransform;
        import mkmap.*;

        public class Viewer extends MovieClip
        {
                private var mCanvas:MCanvas;
                private var mTextInput:TextField;
                private var romkan:RomkanMiniAS = new RomkanMiniAS();
                private var mSearch:RomSearch;
                private var mStData:StationSampleData = new StationSampleData();
                
                private var mOut:TextField;
                private var mLabelPool:Object;
                
                private var mDarkScreen:Sprite;
                private var mDarkCount:int;
                private var mDarkDir:int;
                private var mDarkTransform:ColorTransform = new ColorTransform(0.5, 0.5, 0.5, 1);
                private var mNoTransform:ColorTransform = new ColorTransform();
                
                private const DARK_IN:int = 1;
                private const DARK_OUT:int = -1;
                                
                function Viewer()
                {
                        mDarkScreen = createDarkScreen();
                        mDarkScreen.alpha = 0;
                        mDarkCount = 0;
                        mDarkDir = 0;
                        addChild(mDarkScreen);
                
                        stage.align = StageAlign.TOP_LEFT;
                        stage.scaleMode = StageScaleMode.NO_SCALE;
                        
                        var fmt:TextFormat = new TextFormat();
                        fmt.size = 16;
                        
                        mOut = new TextField();
                        mOut.y = 100;
                        mOut.width = 300;
                        mOut.height = 300;
                        addChild(mOut);
                        setupData();
                        
                        var icon:Loader = new Loader();
                        var url:String = "lens.png";
                        var urlReq:URLRequest = new URLRequest(url);
                        icon.load(urlReq);
                        
                        addChild(icon);                 
                        
                        mTextInput = new TextField();
                        mTextInput.defaultTextFormat = fmt;
                        mTextInput.type = TextFieldType.INPUT;
                        mTextInput.border = true;
                        mTextInput.borderColor = 0xa0afcc;
                        mTextInput.background = true;
                        mTextInput.backgroundColor = 0xffffff;
                        mTextInput.x = 36;
                        mTextInput.y = 9;
                        mTextInput.height = 24;
                        mTextInput.width = 200;
                        mTextInput.addEventListener(Event.CHANGE, onSearchBoxChanged);
                        
                        mCanvas = new MCanvas(900, 500, false, false);
                        mCanvas.x = 48;
                        mCanvas.y = 24;
                        mCanvas.cacheAsBitmap = true;
                        addChild(mCanvas);
                        addChild(mTextInput);
                        mCanvas.objectAdded = onCanvasObjectAdded;
                        
                        mLabelPool = {};
                        mCanvas.deserializeXML(ViewerSampleData.data);
                        addEventListener(Event.ENTER_FRAME, onEnterFrame);
                }
                
                private function onEnterFrame(event:Event):void
                {
                        if (mDarkDir != 0)
                        {
                                mDarkCount += mDarkDir;
                                if (mDarkCount > 5)
                                {
                                        mDarkCount = 5;
                                        mDarkDir = 0;
                                }

                                if (mDarkCount < 0)
                                {
                                        mDarkCount = 0;
                                        mDarkDir = 0;
                                }
                                
                                mDarkScreen.alpha = Number(mDarkCount) * 0.1;
                        }
                }
                                
                private function createDarkScreen():Sprite
                {
                        var s:Sprite = new Sprite();
                        var g:Graphics = s.graphics;
                        g.lineStyle();
                        g.beginFill(0, 1);
                        g.drawRect(0, 0, 900, 500);
                        g.endFill();
                        
                        return s;                       
                }
                
                private function onCanvasObjectAdded(obj:CanvasObject):void
                {
                        if (obj is MTitleBox)
                        {
                                MTitleBox(obj).showDotLabel(false);
                                var name:String = MTitleBox(obj).title;
                                mLabelPool[name] = obj;
                        }
                }
                
                private function setupData():void
                {
                        var len:int = mStData.data.length;
                        var i:int;
                        mSearch = new RomSearch();
                        for (i = 0;i < len;i++)
                        {
                                var st:StationData = mStData.data[i];
                                mSearch.push(st.name, st.kana, st);
                        }
                        

                }
                
                private function onSearchBoxChanged(e:Event):void
                {
                        mOut.text = "";
                        var res:Array = mSearch.search(romkan.to_kana(mTextInput.text));
                        if (res != null)
                        {
                                mOut.text = res.join("\n");
                                
                                mDarkDir = DARK_IN;
                        }
                        else
                                mDarkDir = DARK_OUT;
                        highlightStationList(res);
                }
                
                private function highlightStationList(stations:Array):void
                {
                        var o:Object;
                        var toHighlight:Object = {};
                        if (stations != null)
                                for each(o in stations)
                        {
                                var st:StationData = StationData(o);
                                toHighlight[st.name] = true;
                        }

                        for each(o in mLabelPool)
                        {
                                var label:MTitleBox = MTitleBox(o);
                                if (toHighlight[label.title] || stations == null)
                                {
                                        label.transform.colorTransform = mNoTransform;
                                        label.showDotLabel(true);
                                }
                                else
                                {
                                        label.transform.colorTransform = mDarkTransform;
                                        label.showDotLabel(false);
                                }
                        }
                }
                
                private function makeArrowSprite():Sprite
                {
                        var s:Sprite = new Sprite();
                        var g:Graphics = s.graphics;
                        g.lineStyle(1, 0xffdd66);
                        g.beginFill(0xff8822);
                        g.moveTo(0,0);
                        g.lineTo(-10,-10);
                        g.lineTo(-5,-10);
                        g.lineTo(-5,-20);
                        g.lineTo( 5,-20);
                        g.lineTo( 5,-10);
                        g.lineTo(10,-10);
                        g.lineTo(0,0);
                        g.endFill();
                        
                        return s;
                }
        }
}