root/lang/actionscript/nico/nico.mxml

<?xml version="1.0" encoding="utf-8"?>
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" width="547" height="348" applicationComplete="init()">
        <mx:Script>
                <![CDATA[
                        import vc.kan.nico.CommentField;
                        import mx.controls.Label;
                        import mx.events.CuePointEvent;
                        import flash.filesystem.FileStream;
                        import mx.events.VideoEvent;
                        import vc.kan.net.NicoVideo;
                        import vc.kan.data.DBObject;
                        import flash.filesystem.File;
                        import flash.filesystem.FileMode;
                        import flash.filesystem.FileStream;

                        private var videoDB:DBObject = new DBObject(VideoData);
                        private var seeking:Boolean = false;
                        
                        [Embed(source='assets/play.png')]
                        [Bindable]
                        private var playIcon:Class;
                        
                        [Embed(source='assets/pause.png')]
                        [Bindable]
                        private var pauseIcon:Class;
                        
                        private function init():void {
                                var data:Array = new Array();
                                videoDB.find(function (videos:Array):void {
                                        videos.forEach(function(video:Object, idx:int, ary:Array):void {
                                                data.push({label: video.title, data: video.video_id});
                                        });
                                        list.dataProvider = data;
                                });
                        }
                        
                        private function getData():void {
                                var nico:NicoVideo = new NicoVideo(login_user_id.text, login_user_pass.text);
                                nico.download(nico_id.text, function():void {
                                        init();
                                });
                        }
                        
                        private function selectList(evt:Event):void {
                                var video_id:String = list.selectedItem.data;
                                var video_file:File = File.applicationStorageDirectory.resolve(video_id + ".flv");
                                video.source = video_file.nativePath;
                                
                                var xml_file:File = File.applicationStorageDirectory.resolve(video_id + ".xml");
                                var fsr:FileStream = new FileStream();
                                fsr.open(xml_file, FileMode.READ);
                                var packet:XML = new XML(fsr.readMultiByte(xml_file.size, "utf-8"));
                                fsr.close();
                                
                                var cue:Array = new Array();
                                for each (var chat:XML in packet.chat) {
                                        trace(chat.toString() + "," + chat.@vpos);
                                        cue.push({ name: chat.toString()+" ", time: int(chat.@vpos)/100 });
                                }
                                video.cuePointManager.removeAllCuePoints();
                                video.cuePointManager.setCuePoints(cue);
                                video.play();
                        }
                        
                        private function headUpdate(evt:VideoEvent):void {
                                if (this.seeking) {
                                        return;
                                }
                                seekBar.maximum = video.totalTime;
                                seekBar.value = evt.playheadTime;
                                
                                this.status = getTimeString(evt.playheadTime) + "/" + getTimeString(video.totalTime);
                        }
                        
                        private function getTimeString(second:Number):String {
                                var hour:int = 0;
                                var min:int = second / 60;
                                var sec:int = second % 60;
                                
                                if (min >= 60) {
                                        hour = min / 60;
                                        min = min % 60;
                                }
                                
                                return pad0(hour) + ":" + pad0(min) + ":" + pad0(sec);
                        }
                        
                        private function pad0(num:int):String {
                                if (num < 10) {
                                        return "0" + String(num);
                                } else {
                                        return String(num);
                                }
                        }
                        
                        private function seekStart(evt:Event):void {
                                this.seeking = true;
                        }
                        
                        private function seek(evt:Event):void {
                                video.playheadTime = seekBar.value;
                                this.seeking = false;
                        }
                        
                        private function togglePlay():void {
                                if (video.playing) {
                                        video.pause();
                                } else {
                                        video.play();
                                }
                        }
                        
                        private function stateChange(evt:VideoEvent):void {
                                if (evt.state == VideoEvent.PLAYING) {
                                        playerBtn.source = this.pauseIcon;
                                } else {
                                        playerBtn.source = this.playIcon;
                                }
                        }
                        
                        private function volumeChange():void {
                                video.volume = volumeBar.value;
                        }
                        
                        private function cuePoint(event:CuePointEvent):void {
                                var comment:CommentField = new CommentField();
                                comment.start(video, event.cuePointName);
                        }
                ]]>
        </mx:Script>
        <mx:HDividedBox x="0" y="0" width="100%" height="100%">
                <mx:VBox width="70%" height="100%">
                        <mx:VideoDisplay x="0" y="0" width="100%" height="100%" id="video" 
                            cuePointManagerClass="mx.controls.videoClasses.CuePointManager"
                                playheadUpdate="headUpdate(event)"
                                stateChange="stateChange(event)"
                                cuePoint="cuePoint(event)" />
                        <mx:HBox width="100%" height="20">
                                <mx:Image id="playerBtn" source="{playIcon}" x="10" y="10" click="togglePlay()" />
                                <mx:HSlider id="seekBar" width="100%" height="18" minimum="0" snapInterval="1" 
                                        mouseDown="seekStart(event)" 
                                        thumbPress="seekStart(event)" 
                                        thumbRelease="seek(event)" 
                                        mouseUp="seek(event)" />
                                <mx:Image source="@Embed('assets/volume.png')" />
                                <mx:HSlider id="volumeBar" width="50" height="18" minimum="0" maximum="1" snapInterval="0.01" value="0.75" 
                                        change="volumeChange()" />
                        </mx:HBox>
                </mx:VBox>
                <mx:Canvas width="30%" height="100%">
                        <mx:Label x="0" y="2" text="ID" />
                        <mx:Label x="0" y="28" text="Pass" />
                        <mx:TextInput x="39" y="0" id="login_user_id" width="121"/>
                        <mx:TextInput x="39" y="26" id="login_user_pass" displayAsPassword="true" width="121"/>
                        <mx:Button x="76" y="56" label="get data" click="getData()"/>
                        <mx:TextInput x="0" y="56" width="75" id="nico_id"/>
                        <mx:List x="0" y="86" width="100%" height="260" id="list" click="selectList(event)"></mx:List>
                </mx:Canvas>
        </mx:HDividedBox>
</mx:WindowedApplication>