root/lang/cplusplus/llv8call/trunk/ext/SConscript @ 19827

import platform
from distutils import sysconfig

Import("env")
Import("conf")

def GuessOS():
  id = platform.system()
  if id == 'Linux':
    return 'linux'
  elif id == 'Darwin':
    return 'macos'
  elif id == 'Windows':
    return 'win32'
  else:
    return None

OS_GUESS = GuessOS()

env.Append(
    CCFLAGS = ['-DUSING_V8_SHARED'],
    CPPPATH = ['../../v8/include/', '../src/', '/opt/local/include/', sysconfig.get_python_inc()],
    LIBPATH = ['../../v8/'],
)

if conf.CheckCHeader("Python.h"):
    env.SharedLibrary(
        "python",
        ['python.cc'],
        LIBS=['v8', 'python' + sysconfig.get_config_var('VERSION')],
    )

# libmemcached
if conf.CheckLib('memcached'):
    env.SharedLibrary(
        "libmemcached",
        ['libmemcached.cc'],
        LIBS=['v8', 'memcached'],
    )
elif OS_GUESS == 'win32':
    env.SharedLibrary(
        "memcached",
        ['libmemcached-win32.cc'],
        LIBS=['v8', 'ws2_32'],
    )

if OS_GUESS == 'linux' or OS_GUESS == 'macos':
    env.SharedLibrary(
        "posix",
        ['posix.cc'],
        LIBS=['v8'],
    )

# curl
if conf.CheckLib('curl'):
    libs = ['v8', 'curl']
    if conf.CheckLib('iconv') or OS_GUESS == 'macos':
        libs.append('iconv')
    env.SharedLibrary(
        "curl",
        ['curl.cc'],
        LIBS=libs,
    )

# fcgi
if conf.CheckLib('fcgi'):
    env.SharedLibrary(
        "fcgi",
        ['fcgi.cc'],
        LIBS=['v8', 'fcgi'],
    )

# sqlite3
env.SharedLibrary(
    "sqlite3",
    ["sqlite3-amalgamination.c", 'sqlite3.cc'],
    LIBS=['v8'],
)