root/lang/javascript/jsmml/trunk/src/JSMML.as @ 639

/*
 * Author: Yuichi Tateno
 * http://rails2u.com/
 *
 * The MIT Licence.
 */

package {
    import flash.display.Sprite;
    import flash.utils.Timer;
    import flash.events.TimerEvent;
    import flash.external.ExternalInterface;
    import flash.system.Security;
    import flash.events.Event;

    public class JSMML extends Sprite {
        public static const VERSION:String = '1.0.2';

        public var mmlPlayers:Object = {};

        public function JSMML() {
            Security.allowDomain('*');
            initJS();
        }

        public const CALLBACKS:Array = ['create', 'play', 'stop' ,'pause', 'destroy'];
        public function initJS():void {
            ExternalInterface.call('JSMML.setSWFVersion', JSMML.VERSION);
            for each(var cName:String in CALLBACKS) {
                ExternalInterface.addCallback('_' + cName, this[cName]);
            }
            ExternalInterface.call('JSMML.initASFinish()');
        }

        public function create():Number {
            var uNum:Number = getUNum();
            mmlPlayers[uNum] = new MMLPlayer();
            player(uNum).addEventListener(Event.COMPLETE, playerCompleteHandlerBindNum(uNum));
            return uNum;
        }

        public function getUNum(uNum:Number = NaN):Number {
            if (isNaN(uNum)) {
                uNum = (new Date).getTime();
            } else {
                uNum++;
            }

            if (mmlPlayers[uNum]) {
                return getUNum(uNum);
            } else {
                return uNum;
            }
        }

        public function playerCompleteHandlerBindNum(uNum:Number):Function {
            return function(e:*):void {
                ExternalInterface.call('JSMML.instances["' + uNum + '"].onFinish()');
            };
        }

        public function removeFinishCallback(uNum:Number, func:Function):void {
            player(uNum).removeEventListener(Event.COMPLETE, func);
        }

        public function play(uNum:Number, mml:String = undefined):void {
            if (mml) setMML(uNum, mml);
            player(uNum)._play();
        }

        /*
        public function time(uNum:Number):Number {
            return player(uNum).time;
        }
        */

        public function setMML(uNum:Number, mml:String):void {
            player(uNum).setMML(mml);
        }

        public function stop(uNum:Number):void {
            player(uNum).stop();
        }

        public function pause(uNum:Number):void {
            player(uNum).pause();
        }

        public function destroy(uNum:Number):void {
            stop(uNum);
            delete mmlPlayers[uNum];
        }

        public function player(uNum:Number):MMLPlayer {
            if (!mmlPlayers[uNum]) new Error("Player is not found: " + uNum);
            return mmlPlayers[uNum];
        }
    }
}

import com.txt_nifty.sketch.flmml.MML;
import com.txt_nifty.sketch.flmml.MOscillator;
import flash.events.Event;

internal class MMLPlayer extends MML {
    public function MMLPlayer(mml:String = undefined) {
        super();
        var self:MMLPlayer = this;
        m_sequencer.addEventListener(Event.COMPLETE, function(e:Event):void {
            self.dispatchEvent(new Event(Event.COMPLETE));
        });
        if (mml) setMML(mml);
    }

    // original code form MML#play
    public function setMML(str:String):void {
        m_sequencer.disconnectAll();
        m_tracks = new Array();
        m_tracks[0] = createTrack();
        m_sequencer.connect(m_tracks[0]);

        m_trackNo = 0;
        m_octave = 4;
        m_velocity = 100;
        m_length = 4;
        m_tempo  = 120;
        m_keyoff = 1;
        m_gate = 15;
        m_maxGate = 16;
        m_form = MOscillator.PULSE;

        processMacro(str);
        m_string = removeWhitespace(m_string);
        processRepeat();
        //trace("string "+m_string);
        process();

        // add ends of tracks
        for(var i:int = 0; i < m_tracks.length; i++) {
            m_tracks[i].recRest(384);
            m_tracks[i].recEOT();
        }
        // play start
    }

    /*
    public function get time():Number {
        return m_sequencer.now;
    }
    */

    // MML#proxy don't override because the method call on arg.
    public function _play():void {
        // play start
        m_sequencer.play();
    }

    public override function stop():void {
        super.stop();
        m_sequencer.disconnectAll();
    }

    public function pause():void {
        m_sequencer.stop();
    }

}