root/lang/javascript/jsmml/trunk/vendor/flmml/com/txt_nifty/sketch/flmml/MEnvelope.as @ 447

package com.txt_nifty.sketch.flmml {
        /**
         * This class was created based on "ADSREnvelope.as".
           The original code is in "nu.mine.flashnet.sound.synthesis".
           See following URL; http://www.flexiblefactory.co.uk
           Thanks to his great works!
        */

        import de.popforge.audio.output.*;

        public class MEnvelope {
                public  var m_attack:Number;
                public  var m_decay:Number;
                public  var m_sustain:Number;
                public  var m_release:Number;
                private var m_currentVal:Number;
                private var m_releaseStep:Number;
                private var m_releasing:Boolean;
                private var m_playing:Boolean;
                private var m_timeInSamples:int;
                private var m_startAmplitude:Number;

                public function MEnvelope(attack:Number, decay:Number, sustain:Number, release:Number) {
                        m_playing = false;
                        m_attack  = attack;
                        m_decay   = decay;
                        m_sustain = sustain;
                        m_release = release;
                        m_currentVal = 0;
                        m_releasing = true;
                        m_releaseStep = 0;
                }

                public function setAD(attack:Number, decay:Number):void {
                        m_attack  = attack;
                        m_decay   = decay;
                }

                public function setSR(sustain:Number, release:Number):void {
                        m_sustain = sustain;
                        m_release = (release > 0) ? release : 1;
                }
                
                public function triggerEnvelope():void {
                        m_playing = true;
                        m_releasing = false;
                        m_startAmplitude = m_currentVal;
                        m_timeInSamples = 1; //no point in starting at zero as this gives a sample worth of zero before onset of env.
                }
                
                public function releaseEnvelope():void {
                        m_releasing = true;
                        var releaseTimeInSamples:int = (m_release * Audio.RATE44100);
                        m_releaseStep = (m_currentVal / releaseTimeInSamples);
                }
                
                public function getNextAmplitude():Number {
                        if (!m_playing) return 0;
                        var val:Number;
                        var offset:Number = (m_timeInSamples as Number) / Audio.RATE44100;
                        
                        if (!m_releasing) {
                                if (offset < m_attack) {                                   // attack phase
                                        val = m_startAmplitude + (1 - m_startAmplitude) * offset / m_attack;
                                }
                                else if (offset < (m_attack + m_decay)) {  //decay phase
                                        val = 1.0 - ((offset - m_attack) / m_decay) * (1.0 - m_sustain);
                                }
                                else if (offset >= (m_attack + m_decay)) { //sustain phase
                                        val = m_sustain;
                                }
                        }
                        else {
                                val = m_currentVal - m_releaseStep;                //release phase
                        }
                        
                        if (val < 0) {
                                m_playing = false;
                        }
                        m_currentVal = Math.max(0, val);
                        ++m_timeInSamples;
                        return m_currentVal;
                }
        }
}