root/lang/javascript/jsmml/trunk/vendor/flmml/com/txt_nifty/sketch/flmml/MSequencer.as @ 447

package com.txt_nifty.sketch.flmml {
        import de.popforge.audio.output.*;
        import flash.events.Event;
        import flash.events.EventDispatcher;
        
        public class MSequencer extends EventDispatcher {
                public var onSignal:Function;
                
                protected static const STATUS_STOP:int          = 0;
                protected static const STATUS_BUFFERING:int = 1;
                protected static const STATUS_PLAY:int          = 2;
                protected var m_audioBuffer:AudioBuffer;
                protected var m_trackArr:Array;
                protected var m_volume:int;                              // master volume (max:127)
                protected var m_signalArr:Array;
                protected var m_signalPtr:int;
                protected var m_globalTick:uint;
                protected var m_status:int;
                protected var m_signalInterval:int;

                public function MSequencer(multiple:uint = 16) {
                        MOscillator.boot();
                        m_trackArr = new Array();
                        m_volume = 100;
                        m_signalArr = new Array(4);
                        for(var i:int = 0; i < m_signalArr.length; i++) {
                                m_signalArr[i] = new MSignal(i);
                                m_signalArr[i].setFunction(onSignalHandler);
                        }
                        m_signalPtr = 0;
                        m_audioBuffer = new AudioBuffer(multiple, Audio.STEREO, Audio.BIT16, Audio.RATE44100);
                        m_audioBuffer.onInit     = onAudioBufferInit;
                        m_audioBuffer.onComplete = onAudioBufferComplete;
                        m_status = STATUS_STOP;
                        m_signalInterval = 96/4;
                }

                public function play():void {
                        stop();
                        m_globalTick = 0;
                        m_audioBuffer.start();
                }

                public function pause():void {
                        m_audioBuffer.stop();
                        m_status = STATUS_PLAY;
                }

                public function stop():void {
                        m_audioBuffer.stop();
                        m_status = STATUS_STOP;
                }

                public function isPlaying():Boolean {
                        return (m_status == STATUS_PLAY);
                }

                public function disconnectAll():void {
                        while(m_trackArr.pop());
                }

                public function connect(track:MTrack):void {
                        track.m_signalInterval = m_signalInterval;
                        m_trackArr.push(track);
                }

                public function getGlobalTick():uint {
                        return m_globalTick;
                }

                public function setSignalInterval(interval:int):void {
                        m_signalInterval = interval;
                }

                protected function onSignalHandler(globalTick:uint, event:int):void {
                        m_globalTick = globalTick;
                        if (onSignal != null) onSignal(globalTick, event);
                }

                private function onAudioBufferInit(buffer:AudioBuffer):void {
                        buffer.start();
                }

                private function onAudioBufferComplete(buffer:AudioBuffer):void {
                        //var starttime:Date = new Date();
                        var samples:Array = buffer.getSamples();
                        var amplitude:Number;
                        var sample:Sample;
                        var i:int;
                        var sLen:int = samples.length;
                        for(i = 0; i < sLen; i++) {
                                sample = samples[i];
                                sample.left = sample.right = 0.0 ;
                        }
                        var signal:MSignal = m_signalArr[m_signalPtr];
                        var nt:int = m_trackArr.length;
                        if (nt > 0) {
                                var track:MTrack = m_trackArr[0];
                                track.onAudioBufferComplete(samples, signal);
                                for(i = 1; i < nt; i++) {
                                        track = m_trackArr[i];
                                        track.onAudioBufferComplete(samples);
                                }
                        }
                        var mvol:Number = m_volume * (0.5 / 127.0);
                        for(i = 0; i < sLen; i++) {
                sample = samples[i];
                                sample.left      *= mvol;
                                sample.right *= mvol;
                        }
                        buffer.update();

                        // end of sequence
                        var n:int = 0;
                        for (i = 0; i < m_trackArr.length; i++) {
                                if (m_trackArr[i].isEnd()) n++;
                        }
                        if (n >= m_trackArr.length) {
                                buffer.stop();
                                dispatchEvent(new Event(Event.COMPLETE));
                        }

                        m_signalArr[(m_signalPtr + m_signalArr.length-1) % m_signalArr.length].start();
                        if (m_status < STATUS_PLAY) {
                                m_status++;
                        }
                        m_signalPtr = (++m_signalPtr) % m_signalArr.length;

                        //var endtime:Date = new Date();
                        //trace((endtime.getTime() - starttime.getTime()) + "msec.");
                }
        }
}