root/lang/objective-cplusplus/i3/trunk/configure.ac @ 31446

#                                               -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.

AC_PREREQ(2.60)
AC_INIT([i3],[0.1alpha],[dyob@lunaport.net])
AC_CONFIG_AUX_DIR([build-aux])
#AM_INIT_AUTOMAKE([gnu no-define check-news std-options tar-pax filename-length-max=99])
AM_INIT_AUTOMAKE([gnu no-define check-news std-options])
AC_CONFIG_SRCDIR([src/Main.cpp])
AC_CONFIG_HEADER([config.h])

# ---------------------------------------
# this should be set before AC_PROG_CC, AC_USE_SYSTEM_EXTENSIONS
AC_ARG_ENABLE(debug,
    AS_HELP_STRING([--enable-debug], [build debug binaries]),
        enable_debug="$enableval", enable_debug="no")
AM_CONDITIONAL(ENABLE_DEBUG, test "$enable_debug" = "yes")
if test "$enable_debug" = "yes"; then
  if test "$CFLAGS" = ""; then
    CFLAGS="-O0 -g"
  fi
  if test "$CXXFLAGS" = ""; then
    CXXFLAGS="-O0 -g"
  fi
fi

# ---------------------------------------
# Programs
AC_USE_SYSTEM_EXTENSIONS
AC_CANONICAL_HOST
AC_PROG_CC
AC_PROG_CXX
AC_LANG([C++])

AM_CONDITIONAL(USE_GCH, test "$GXX" = "yes")

# ---------------------------------------
# OS

case "$host_os" in
    mingw*)
        with_os=windows
        with_gui_default=gnustep
        ;;
    cygwin*)
        with_os=unix
        with_gui_default=windows
        with_cygwin=yes
        ;;
    darwin*)
        with_os=unix
        with_gui_default=cocoa
        ;;
    *)
        with_os=unix
        with_gui_default=gnustep
        ;;
esac

AC_ARG_WITH(gui,
    AS_HELP_STRING([--with-gui={cocoa|gnustep|windows}], [gui]),
        with_gui="$withval", with_gui=$with_gui_default)

case "$with_gui" in
    windows)
    ;;
    cocoa)
        CXXFLAGS="$CXXFLAGS -x objective-c++"
        LDFLAGS="$LDFLAGS -x none -framework Cocoa"
    ;;
    gnustep)
        which gnustep-config > /dev/null
        if test $? -ne 0; then
            AC_MSG_WARN([gnustep-config not found])
        fi

        if test "$enable_debug" = "yes"; then
            debug_arg="--debug"
        fi

        CXXFLAGS="$CXXFLAGS -x objective-c++ `perl $srcdir/scripts/gnustep-config-filter.pl $debug_arg gnustep-config --objc-flags`"
        LDFLAGS="$LDFLAGS -x none"
        LIBS="$LIBS `perl $srcdir/scripts/gnustep-config-filter.pl $debug_arg gnustep-config --gui-libs`"
        with_gui=cocoa
    ;;
    *)
        AC_MSG_ERROR([--with-gui=$with_gui is invalid])
    ;;
esac

OS_DIR="os-$with_os"
GUI_DIR="gui-$with_gui"
AC_SUBST(OS_DIR)
AC_SUBST(GUI_DIR)

AM_CONDITIONAL(WITH_CYGWIN,      test "$with_cygwin" = "yes")
AM_CONDITIONAL(WITH_OS_WINDOWS,  test "$with_os"     = "windows")
AM_CONDITIONAL(WITH_OS_UNIX,     test "$with_os"     = "unix")
AM_CONDITIONAL(WITH_GUI_WINDOWS, test "$with_gui"    = "windows")
AM_CONDITIONAL(WITH_GUI_COCOA,   test "$with_gui"    = "cocoa")

if test "$with_gui" != "windows"; then   
    AC_MSG_CHECKING([objective-c++])
    prologue="class Foo {}; @interface Bar {} @end @implementation Bar @end"
    body="Foo foo; Bar* bar;"
    AC_COMPILE_IFELSE(
        [AC_LANG_PROGRAM([[$prologue]], [[$body]])],
            [],
            [AC_MSG_FAILURE([objective-c++ compiler not found])])
    LDFLAGS_ORIG="$LDFLAGS"
    LDFLAGS="$LDFLAGS -x objective-c++"
    AC_LINK_IFELSE(
        [AC_LANG_PROGRAM([[$prologue]], [[$body]])],
            [AC_MSG_RESULT([yes])],
            [AC_MSG_FAILURE([objective-c++ linker does not work])])
    LDFLAGS="$LDFLAGS_ORIG"
fi

# ---------------------------------------
# Libraries

#
# boost
#

AX_BOOST_BASE([1.38.0])
#AX_BOOST_PROGRAM_OPTIONS
#AX_BOOST_UNIT_TEST_FRAMEWORK

#
# pthread
#

ACX_PTHREAD

#
# gettext
#

AC_LANG_PUSH([C])
AM_GNU_GETTEXT_VERSION([0.16.1])
AM_GNU_GETTEXT
AC_LANG_POP

# ---------------------------------------
# Checks for header files.
AC_CHECK_HEADERS([popt.h xbyak.h cstdatomic])

# ---------------------------------------
# Checks for typedefs, structures, and compiler characteristics.

# ---------------------------------------
# Checks for library functions.

#AC_CHECK_LIB([argtable2],[arg_parse], [], [echo "argtable2 not found"])

#
# popt
#

AC_CHECK_LIB([popt],[poptGetContext], 
    [
        LIBS="$LIBS -lpopt $LIBINTL"
    ], 
    [
        AC_CHECK_LIB([popt],[poptFreeContext], [], [echo "popt not found"])
    ],
    ["$LIBINTL"])

#
# wbindtextdomain
#

LIBS_ORIG="$LIBS"
LIBS="$LIBS $LIBINTL"
AC_CHECK_FUNCS([wbindtextdomain])
LIBS="$LIBS_ORIG"

#
# atomic operations
#
AC_MSG_CHECKING([for __sync_bool_compare_and_swap])
prog="int data = 0;  __sync_bool_compare_and_swap(&data, 0, 1);"
AC_LINK_IFELSE(
    [AC_LANG_PROGRAM([[]], [[$prog]])],
    [AC_MSG_RESULT([yes])],
    [
        CXXFLAGS="$CXXFLAGS -march=$host_cpu"
        AC_LINK_IFELSE(
            [AC_LANG_PROGRAM([[]], [[$prog]])],
                [AC_MSG_RESULT([yes])],
                [AC_MSG_FAILURE([__sync_bool_compare_and_swap not found])])])

#
# autotest
#

AC_CONFIG_TESTDIR([tests])
AC_CONFIG_FILES([tests/Makefile tests/atlocal])

# ---------------------------------------
AC_CONFIG_FILES([Makefile intl/Makefile po/Makefile.in])
AC_OUTPUT

echo "Then type 'make' to make ${PACKAGE_NAME}. Good luck. "