root/lang/objective-cplusplus/i3/trunk/configure.ac @ 35844

#                                               -*- Autoconf -*-
# Process this file with autoconf to produce a configure script.

AC_PREREQ(2.60)
AC_INIT([i3],[m4_esyscmd(./scripts/ac_init_version.sh | tr -d '\r\n')],[dyob@lunaport.net])

CFLAGS_before_configure="$CFLAGS"
CXXFLAGS_before_configure="$CXXFLAGS"
OBJCFLAGS_before_configure="$OBJCFLAGS"

AC_CONFIG_AUX_DIR([build-aux])
AM_INIT_AUTOMAKE([-Wall gnu no-define std-options filename-length-max=99])
#AM_INIT_AUTOMAKE([-Wall gnu no-define check-news std-options filename-length-max=99 color-tests])
AC_CONFIG_SRCDIR([src/Main.cpp])
AC_CONFIG_HEADER([config.h])

# ---------------------------------------
# Programs
AC_USE_SYSTEM_EXTENSIONS
AC_CANONICAL_HOST
AC_PROG_CC
AC_PROG_CXX
AC_PROG_OBJC
AC_LANG([C++])

AC_ARG_ENABLE(debug,
              AS_HELP_STRING([--enable-debug], [build debug binaries]),
              enable_debug="$enableval", 
#              enable_debug="no"
              enable_debug="yes"
                           )
AM_CONDITIONAL(ENABLE_DEBUG, test "$enable_debug" = "yes")
if test "$enable_debug" = "yes"; then
    if test "$CFLAGS_before_configure" = ""; then
        CFLAGS="-O0 -g"
    fi
    if test "$CXXFLAGS_before_configure" = ""; then
        CXXFLAGS="-O0 -g"
    fi
    if test "$OBJCFLAGS_before_configure" = ""; then
        OBJCFLAGS="-O0 -g"
    fi
fi

# ---------------------------------------
# OS

case "$host_os" in
    mingw*)
        with_os=windows
        with_gui_default=windows
        ;;
    cygwin)
        with_os=unix
        with_gui_default=windows
        with_cygwin=yes
        ;;
    darwin*)
        with_os=unix
        with_gui_default=cocoa
        ;;
    *)
        with_os=unix
        with_gui_default=gnustep
        ;;
esac

AC_ARG_WITH(gui,
    AS_HELP_STRING([--with-gui={cocoa|gnustep|windows}], [gui]),
        with_gui="$withval", with_gui=$with_gui_default)

case "$with_gui" in
    windows)
        GCH_LANG="c++-header"
    ;;
    cocoa)
        GCH_LANG="objective-c++-header"
        CXXFLAGS="$CXXFLAGS -xobjective-c++"
        LDFLAGS="$LDFLAGS -xnone -framework Cocoa"
    ;;
    gnustep)
        with_gui=cocoa
        GCH_LANG="objective-c++-header"
        CXXFLAGS="$CXXFLAGS -xobjective-c++"
        LDFLAGS="$LDFLAGS -xnone"

        #AC_CHECK_PROG(GNUSTEP_CONFIG, gnustep-config)
        which gnustep-config > /dev/null
        if test $? -eq 0; then
            GNUSTEP_CONFIG="gnustep-config"
            if test "$enable_debug" = "yes"; then
                debug_arg="--debug"
            fi

            #AC_CHECK_PROG(GNUSTEP_CONFIG, perl)
            which perl > /dev/null
            if test $? -eq 0; then
                GNUSTEP_CONFIG="perl $srcdir/scripts/gnustep-config-filter.pl $debug_arg $GNUSTEP_CONFIG"
            else
                AC_MSG_WARN([perl not found])
            fi

            OBJCFLAGS="$OBJCFLAGS `$GNUSTEP_CONFIG --objc-flags`"
            CXXFLAGS="$CXXFLAGS `$GNUSTEP_CONFIG --objc-flags`"
            LIBS="$LIBS `$GNUSTEP_CONFIG --gui-libs`"
        else
            AC_MSG_WARN([gnustep-config not found])
        fi
    ;;
    *)
        AC_MSG_ERROR([--with-gui=$with_gui is invalid])
    ;;
esac

if test "$with_gui" != "windows"; then
    AC_MSG_CHECKING([objective-c++])
    prologue="class Foo {}; @interface Bar {} @end @implementation Bar @end"
    body="Foo foo; Bar* bar;"
    LDFLAGS_ORIG="$LDFLAGS"
    LDFLAGS="$LDFLAGS -xobjective-c++"
    AC_LINK_IFELSE(
        [AC_LANG_PROGRAM([[$prologue]], [[$body]])],
        [AC_MSG_RESULT([yes])],
        [AC_MSG_FAILURE([objective-c++ compiler/linker does not work])])
    AC_CHECK_HEADERS([boost/ptr_container/detail/static_move_ptr.hpp boost/detail/is_incrementable.hpp])
    LDFLAGS="$LDFLAGS_ORIG"
fi
AC_CHECK_HEADERS([__NON..EXISTANT--HEADER__FILE__],
                 [AC_MSG_FAILURE([no error when include file is not found])])

AC_SUBST(GCH_LANG)

OS_DIR="os-$with_os"
GUI_DIR="gui-$with_gui"
AC_SUBST(OS_DIR)
AC_SUBST(GUI_DIR)

AM_CONDITIONAL(WITH_CYGWIN,      test "$with_cygwin" = "yes")
AM_CONDITIONAL(WITH_OS_WINDOWS,  test "$with_os"     = "windows")
AM_CONDITIONAL(WITH_OS_UNIX,     test "$with_os"     = "unix")
AM_CONDITIONAL(WITH_GUI_WINDOWS, test "$with_gui"    = "windows")
AM_CONDITIONAL(WITH_GUI_COCOA,   test "$with_gui"    = "cocoa")

# ---------------------------------------
# Libraries

#
# boost
#

AX_BOOST_BASE([1.33.1])

#
# pthread
#

ACX_PTHREAD

#
# gettext
#

AC_LANG_PUSH([C])
AM_GNU_GETTEXT_VERSION([0.17])
#AM_GNU_GETTEXT_VERSION([0.16.1])
#AM_GNU_GETTEXT_VERSION([0.14.5])
AM_GNU_GETTEXT
AC_LANG_POP

# ---------------------------------------
# Checks for header files.

#AC_CHECK_HEADERS([xbyak.h cstdatomic])

# ---------------------------------------
# Checks for typedefs, structures, and compiler characteristics.

# ---------------------------------------
# Checks for library functions.

#
# popt
#

#AC_LANG_PUSH([C])
AC_CHECK_HEADERS(
    [popt.h],
    [AC_CHECK_LIB(
        [popt],
        [poptGetContext], 
        [LIBS="$LIBS -lpopt $LIBINTL"], 
        [AC_CHECK_LIB(
            [popt],
            [poptFreeContext])],
        ["$LIBINTL"])])
#AC_LANG_POP

#
# wbindtextdomain
#

LIBS_ORIG="$LIBS"
LIBS="$LIBS $LIBINTL"
AC_CHECK_FUNCS([wbindtextdomain])
LIBS="$LIBS_ORIG"

#
# atomic operations
#

CXXFLAGS_ORIG="$CXXFLAGS"
AC_MSG_CHECKING([for __sync_bool_compare_and_swap])
prog="int data = 0;  __sync_bool_compare_and_swap(&data, 0, 1);"

gcc_atomic_operations_found() {
    AC_MSG_RESULT([yes]);
    AC_DEFINE(HAVE_GCC_ATOMIC_OPERATIONS,[],[TODO: Description])
}

AC_LINK_IFELSE(
    [AC_LANG_PROGRAM([[]], [[$prog]])],
    [gcc_atomic_operations_found],
    [
        CXXFLAGS="$CXXFLAGS -march=$host_cpu"
        AC_LINK_IFELSE(
            [AC_LANG_PROGRAM([[]], [[$prog]])],
            [gcc_atomic_operations_found],
            [AC_MSG_RESULT([no]); CXXFLAGS="$CXXFLAGS_ORIG"])])

CXXFLAGS_NO_LANG=`echo $CXXFLAGS | sed "s/-xobjective-c++//" -`
AC_SUBST(CXXFLAGS_NO_LANG)

# -Wno-missing-field-initializers
AC_MSG_CHECKING([for -Wno-missing-field-initializers])
CXXFLAGS_ORIG="$CXXFLAGS"
CXXFLAGS="$CXXFLAGS -Wno-missing-field-initializers"
AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], 
                  [AC_MSG_RESULT([yes])],
                  [AC_MSG_RESULT([no]); CXXFLAGS="$CXXFLAGS_ORIG"])

#
# precompiled headers
#

use_gch=no
if test "$GXX" = "yes"; then
    if test "$enable_debug" = "yes"; then
        AC_MSG_CHECKING([for precompiled headers])
        CXXFLAGS_ORIG="$CXXFLAGS"
        output=foo.cpp.gch
        rm -f $output
        if test -e $output; then
            AC_MSG_ERROR([can't remove file '$output'])
        fi
        CXXFLAGS="$CXXFLAGS_NO_LANG -x$GCH_LANG -o $output"
        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], [], [])
        if test -e $output; then
            AC_MSG_RESULT([yes])
            use_gch=yes
        else
            AC_MSG_RESULT([no])
        fi
        rm -f $output
        CXXFLAGS="$CXXFLAGS_ORIG"
    fi
fi
AM_CONDITIONAL(USE_GCC_PRECOMPILED_HEADER, test "$use_gch" = "yes")

#
# autotest
#

AC_CONFIG_TESTDIR([tests])
AC_CONFIG_FILES([tests/Makefile tests/atlocal])

# ---------------------------------------
AC_CONFIG_FILES([Makefile intl/Makefile po/Makefile.in])
AC_OUTPUT

echo "Then type \`make' to make ${PACKAGE_NAME}. Good luck. "