root/lang/perl/Acme-CPANAuthors-CodeRepos/trunk/bin/update.pl @ 12167

#!perl

use strict;
use warnings;
use FindBin;
use lib "$FindBin::Bin/../lib";
use Web::Scraper;
use URI;
use YAML;
use CPAN::Config;
use Parse::CPAN::Authors;
use Template;
use Time::Piece;
use Acme::CPANAuthors::CodeRepos;

my %mapping = (
  # people whose coderepos id is not the same as their pause id
  AMACHANG    => 'ITWARRIOR',
  AUTARCH     => 'DROLSKY',
  CASTAWAY    => 'JROBINSON',
  CHARSBAR    => 'ISHIGAKI',
  CLOUDER     => 'KURIHARA',
  DAISUKE     => 'DMAKI',
  FBIS        => 'MIYAZAKI',
  HANEKOMU    => 'MARCEL',
  HIDEK       => 'HIDE',
  HIROSE31    => 'HIROSE',
  KAN         => 'MIKIHOSHI',
  MARCUS      => 'MRAMBERG',
  MATTHEWT    => 'MSTROUT',
  MOSELEY     => 'HANK',
  NIPOTAN     => 'TANIGUCHI',
  NOTHINGMUCH => 'NUFFIN',
  TAKEMARU    => 'TAKERU',
  VKGTARO     => 'TARO',

  # people whose coderepos id matches other person's pause id
  BULB        => '- other person -',
  DANN        => '- other person -',
  OMEGA       => '- other person -',
);

my $command = shift; # from @ARGV

my $committers;
if ( $command && $command =~ /scraper/ ) {
  my $scraper = scraper {
    process "ul>li>a",
      "committers[]" => sub {
        my $e = shift;
        return unless $e->attr('href') =~ m{/wiki/Committers/(\w+)$};
        return uc $1;
      };
  };

  $committers = $scraper->scrape(
    URI->new('http://coderepos.org/share')
  )->{committers};

  YAML::DumpFile("$FindBin::Bin/coderepos_users.yml", $committers);
}

$committers ||= YAML::LoadFile("$FindBin::Bin/coderepos_users.yml");

my $authors_file;
foreach my $path (
  File::Spec->catdir($CPAN::Config->{keep_source_where}, 'authors'),
  $CPAN::Config->{keep_source_where},
  ""
) {
  $authors_file = File::Spec->catfile( $path, '01mailrc.txt.gz' );
  last if -f $authors_file;
}

my $cpan = Parse::CPAN::Authors->new( $authors_file );

my %cpan_authors = Acme::CPANAuthors::CodeRepos->authors;
foreach my $committer ( @{ $committers || [] } ) {
  my $pause_id = $mapping{$committer} || $committer;

  if ( my $author = $cpan->author($pause_id) ) {
    $cpan_authors{ $pause_id } ||= $author->name;
  }
}

my $target   = "$FindBin::Bin/../lib/Acme/CPANAuthors/CodeRepos.pm";
my $engine   = Template->new;
my $template = get_template();

my $version = localtime(time)->strftime('0.%y%m%d');

$engine->process(
  \$template,
  {
    authors => \%cpan_authors,
    version => $version,
    mapping => \%mapping
  },
  $target,
) or die $engine->error;

sub get_template { return <<"TEMPLATE";
package Acme::CPANAuthors::CodeRepos;

use strict;
use warnings;

our \$VERSION = '[% version %]';

# this is auto-generated by bin/update.pl

use Acme::CPANAuthors::Register (
[% FOREACH author IN authors -%]
    [% author.key %] => '[% author.value %]',
[% END -%]
);

# people whose coderepos id doesn't match their pause id
sub _mapping {(
[% FOREACH committer IN mapping -%]
    [% committer.key %] => '[% committer.value %]',
[% END -%]
)}

1;

\__END__

\=head1 NAME

Acme::CPANAuthors::CodeRepos - We are CPAN authors using CodeRepos

\=head1 DESCRIPTION

This class provides a hash of Pause ID/name of CPAN authors who use CodeRepos, our open source repository.

\=head1 MAINTENANCE

If you are a CodeRepos user and are not listed here, add your own id/name, or preferably update bin/update.pl in the repository (probably modify %mapping would suffice).

\=head1 SVN REPOSITORY

http://svn.coderepos.org/share/lang/perl/Acme-CPANAuthors-CodeRepos/

\=head1 AUTHOR

Kenichi Ishigaki, E<lt>ishigaki\@cpan.orgE<gt>, and others in the CodeRepos repository.

\=head1 COPYRIGHT AND LICENSE

Copyright (C) 2008 by Kenichi Ishigaki.

This program is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

\=cut
TEMPLATE
}