root/lang/perl/Acme-JapaneseCPANAuthors/trunk/lib/Acme/JapaneseCPANAuthors.pm

package Acme::JapaneseCPANAuthors;

use strict;
use warnings;
use Acme::JapaneseCPANAuthors::Registered;
use Acme::JapaneseCPANAuthors::Utils;

our $VERSION = '0.071104';

sub count {
  my $class = shift;

  return scalar keys %JAPANESE_AUTHORS;
}

sub id {
  my ($class, $id) = @_;

  unless ( $id ) {
    return sort keys %JAPANESE_AUTHORS;
  }
  else {
    return $JAPANESE_AUTHORS{$id} ? 1 : 0;
  }
}

sub name {
  my ($class, $id) = @_;

  unless ( $id ) {
    return sort values %JAPANESE_AUTHORS;
  }
  else {
    return $JAPANESE_AUTHORS{$id};
  }
}

sub distributions {
  my ($class, $id) = @_;

  return unless $id;

  require Parse::CPAN::Packages;
  my $cpan = Parse::CPAN::Packages->new( _package_file() );

  my @packages;
  foreach my $package ( $cpan->distributions ) {
    if ( $package->cpanid eq $id ) {
      push @packages, $package;
    }
  }

  return @packages;
}

sub avatar {
  my ($class, $id, %options) = @_;

  return unless $id;

  require Parse::CPAN::Authors;
  require Gravatar::URL;
  my $cpan   = Parse::CPAN::Authors->new( _author_file() );
  my $author = $cpan->author($id);

  return Gravatar::URL::gravatar_url( email => $author->email, %options );
}

1;

__END__

=head1 NAME

Acme::JapaneseCPANAuthors - We are Japanese CPAN authors

=head1 SYNOPSIS

    use Acme::JapaneseCPANAuthors;
    $number  = Acme::JapaneseCPANAuthors->count;
    @ids     = Acme::JapaneseCPANAuthors->id;
    %distros = Acme::JapaneseCPANAuthors->distributions('ISHIGAKI');
    $uri     = Acme::JapaneseCPANAuthors->avatar('MIYAGAWA');

=head1 DESCRIPTION

Sometimes we just want to know something to confirm we're not
alone, or to see if we're doing right things, or to look for
someone we can rely on. This module provides you some basic
information on us.

=head1 METHODS

=head2 count

returns how many (registered) Japanese authors are known,
or at least have some module(s).

=head2 id

returns all the registered ids by default. If called with an
id, this returns if there's a registered Japanese author of
the id.

=head2 name

returns all the registered users' name by default. If called
with an id, this returns the name of the author of the id.

=head2 distributions

returns an array of Parse::CPAN::Packages::Distribution objects
for the person of the id.

=head2 avatar

returns gravatar uri of the id shown at search.cpan.org.
see L<http://site.gravatar.com/site/implement> for details.

=head1 AUTHOR

Kenichi Ishigaki, E<lt>ishigaki at cpan.orgE<gt>

=head1 COPYRIGHT AND LICENSE

Copyright (C) 2007 by Kenichi Ishigaki.

This program is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

=cut