root/lang/perl/Archer/lib/Archer/Shell.pm @ 3690

package Archer::Shell;
use strict;
use warnings;
use Net::SSH;
use Term::ReadLine;
use POSIX;

sub new {
    my ( $class, $args ) = @_;

    return bless { %$args }, $class;
}

sub run_loop {
    my ($self, ) = @_;

    my $term = Term::ReadLine->new('Archer');

    my $HISTFILE = ($ENV{HOME} || ((getpwuid($<))[7])) . "/.archer_shell_history";
    my $HISTSIZE = 256;

    $term->stifle_history($HISTSIZE);
    if (-f $HISTFILE) {
        $term->ReadHistory($HISTFILE) or $self->{context}->log('warn' => "cannot read history file: $!");
    }

    while ( defined( my $line = $term->readline('archer> ') )) {
        next if $line =~ /^\s*$/;
        $self->catch_run($line);
    }

    print "\n";

    $term->WriteHistory($HISTFILE) or $self->{context}->log('warn' => "perlsh: cannot write history file: $!");
}

sub catch_run {
    my ($self, $cmd) = @_;

    my $parallel = $self->{context}->{config}->{global}->{parallel}
        || 'Archer::Parallel::ForkManager';
    $parallel->use or die $@;

    my $manager = $parallel->new;
    $manager->run({
        elems => $self->{servers},
        callback => sub {
            my $server = shift;
            $self->callback($server, $cmd);
        },
        num => $self->{context}->{parallel_num},
    });
}

sub callback {
    my ( $self, $server, $cmd ) = @_;

    Net::SSH::sshopen2( $server, *READER, *WRITER, $cmd );
    while (<READER>) {
        chomp;
        print "[$server] $_\n";
    }
    close READER;
    close WRITER;
}

1;
__END__

=head1 NAME

Archer::Shell - display shell prompt for remote servers.

=head1 DESCRIPTION

Shell prompt for remote servers.

=head1 FILES

    ~/.archer_shell_history

=head1 AUTHORS

    Gosuke Miyashita
    Tokuhiro Matsuno

=head1 SEE ALSO

L<Term::ReadLine>

=cut