root/lang/perl/DBIx-ShardManager/trunk/lib/DBIx/ShardManager.pm @ 35171

package DBIx::ShardManager;

use strict;
use warnings;

use 5.008;
use Carp;
use Class::Accessor::Lite;

our $VERSION = 0.01;

our %Defaults = (
    definition      => undef,
    # hash of connector->to_conn_id->(\%conn_info) => $dbh
    _handles        => undef,
    connector       => undef,
    _slave_sel_seed => int(rand 0x40000000),
);

Class::Accessor::Lite->mk_accessors(keys %Defaults);

sub new {
    my $klass = shift;
    my $self = bless {
        %Defaults,
        @_ == 1 ? %{$_[0]} : @_,
        _handles => {},
    }, $klass;
    confess 'mandatory parameter "definition" is missing'
        unless $self->definition;
    $self->definition->manager($self);
    confess 'mandatory parameter "connector" is missing'
        unless $self->connector;
    $self->connector->manager($self);
    $self;
}

sub flush {
    my $self = shift;
    $self->_handles({});
}

sub rw_handle {
    my ($self, $key) = @_;
    my $conn_info = $self->definition->get_conn_info($key);
    $conn_info = $conn_info->[0]
        if ref $conn_info eq 'ARRAY';
    $self->_handle_for($conn_info);
}

sub read_handle {
    my ($self, $key) = @_;
    my $conn_info = $self->definition->get_conn_info($key);
    if (ref $conn_info eq 'ARRAY' && @$conn_info > 2) {
        $conn_info
            = $conn_info->[1 + $self->_slave_sel_seed % (@$conn_info - 1)];
    }
    $self->_handle_for($conn_info);
}

sub _handle_for {
    my ($self, $conn_info) = @_;
    my $ident = $self->connector->to_ident($conn_info);
    $self->_handles->{$ident} ||= $self->connector->connect($conn_info);
}

1;
__END__

=head1 NAME

DBIx::ShardManager

=head1 SYNOPSIS

  use DBIx::ShardManager;
  
  my $sm = DBIx::ShardManager->new(
      definition => DBIx::ShardManager::Definition::JSON->new(
          file        => 'shard_def.json',
          auto_reload => 1,
      ),
      connector  => DBIx::ShardManager::Connector::DBI->new(
          driver   => 'mysql',
          dbname   => '...',
          username => 'db_user',
          password => 'db_pass',
          attr     => { mysql_enable_utf8 => 1 },
      ),
  );
  
  $sm->handle_for($shard_key)->do(
      'INSERT INTO ...',
  );
  
=cut