root/lang/perl/Data-XMind/trunk/lib/Data/XMind.pm @ 25900

package Data::XMind;

use strict;
use warnings;
use 5.8.1;

our $VERSION = '0.01';

use Archive::Zip qw( :ERROR_CODES :CONSTANTS );

use Data::XMind::Content;
use Data::XMind::Util qw(newid);


sub new {
    my $class = shift;

    my $self = bless {
        @_,
    }, $class;

    $self->{id} ||= newid;

    my $content = Data::XMind::Content->new(
        title => $self->{title},
    );
    $content->{parent} = $self;

    $self->{depth} = 0;
    $self->{content} = $content;
    $self->{last_content} = $self->{content};
    $self->{parent} = undef;

    $self;
}

sub title {
    my $self = shift;

    if (scalar(@_)) {
        $self->{content}->{title} = shift;
    }

    $self->{content}->{title};
}

sub add {
    my $self = shift;
    my $opt = ref($_[0]) ? $_[0] : {@_};

    die unless defined($opt->{depth}) && $opt->{depth} > 0;
    die unless defined($opt->{title}) && length($opt->{title});

    my $opt_depth = $opt->{depth};
    my $last_depth = $self->{last_content}->{depth};

    die if ($opt_depth == 0);

    my $content = Data::XMind::Content->new(
        title => $opt->{title},
    );

    if ($opt_depth < $last_depth) {
        my $done = 0;
        my $last_content = $self->{last_content};
        my $parent;
        while ($parent = $last_content->{parent}) {
            if ($opt_depth == $parent->{depth}) {
                $self->{last_content} = $parent;
                $last_depth = $self->{last_content}->{depth};
                $done++;
                last;
            }
            $last_content = $parent;
        }
        die unless $done;
    }

    if ($opt_depth == $last_depth) {
        $self->{last_content} = $self->{last_content}->{parent}->add($content);
    }
    elsif ($opt_depth == ($last_depth + 1)) {
        $self->{last_content} = $self->{last_content}->add($content);
    }

    $self->{last_content};
}

sub add_note {
    my $self = shift;
    my $str = shift;

    my $content = $self->{last_content};
    $content->add_note($str);
}

my $template = << '__TMPL__';
<?xml version="1.0" encoding="UTF-8" standalone="no"?>
<xmap-content xmlns="urn:xmind:xmap:xmlns:content:2.0" xmlns:fo="http://www.w3.org/1999/XSL/Format" xmlns:svg="http://www.w3.org/2000/svg" xmlns:xhtml="http://www.w3.org/1999/xhtml" xmlns:xlink="http://www.w3.org/1999/xlink" version="2.0">
<sheet id="[% id %]">
<title>[% title %]</title>
[%- content -%]
</sheet>
</xmap-content>
__TMPL__

sub as_xml {
    my $self = shift;

    my $vars = {
        id => $self->{id},
        title => $self->{title},
        content => $self->{content}->as_xml,
    };

    my $tt = Template->new;
    $tt->process(\$template, $vars, \my $xml) or die $tt->error();

    $xml;
}

sub as_xmind {
    my $self = shift;
    my $basename = scalar(@_) ? shift : time();

    my $name = $basename . ".xmind";
    my $zip = Archive::Zip->new;

    my %data = (
        'meta.xml' => '<?xml version="1.0" encoding="UTF-8" standalone="no"?><meta xmlns="urn:xmind:xmap:xmlns:meta:2.0" version="2.0"/>',
        'content.xml' => $self->as_xml,
        'META-INF/manifest.xml' => '<?xml version="1.0" encoding="UTF-8" standalone="no"?><manifest xmlns="urn:xmind:xmap:xmlns:manifest:1.0"><file-entry full-path="content.xml" media-type="text/xml"/><file-entry full-path="META-INF/" media-type=""/><file-entry full-path="META-INF/manifest.xml" media-type="text/xml"/></manifest>',
    );

    while (my ($key, $val) = each(%data)) {
        my $str = $zip->addString($val, $key);
        $str->desiredCompressionMethod(COMPRESSION_DEFLATED);
    }

    unless ($zip->writeToFileNamed($name) == AZ_OK) {
        die 'write error';
    }
}

1;
__END__

=encoding utf-8

=for stopwords

=head1 NAME

Data::XMind - generates XMind file

=head1 SYNOPSIS

  use Data::XMind;

  my $obj = Data::XMind->new(title => "woremacx");

  $obj->add(title => "blogs", depth => 1);
  $obj->add_note("about blogs written by woremacx");

  $obj->add(title => "blog.woremacx.com", depth => 2);
  $obj->add_note("http://blog.woremacx.com/");

  $obj->add(title => "woremacx diary", depth => 2);
  $obj->add_note("http://d.hatena.ne.jp/");

  $obj->as_xmind("woremacx"); # you will get woremacx.xmind


=head1 DESCRIPTION

Data::XMind generates XMind file.

eg/xmind_from_text.pl and eg/xmind_from_text_result.xmind are simple examples.

=head1 METHODS

=head2 title

set title of first element

=head2 add

make a new element and put it in to appropriate element by depth

=head2 add_note

add note to last added element

=head2 as_xml

generate content.xml

=head2 as_xmind

generate xmind file

=head1 AUTHOR

woremacx E<lt>woremacx@cpan.orgE<gt>

=head1 LICENSE

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.

=head1 SEE ALSO

=cut