root/lang/perl/Flickr2Twitter/xmlrpc.cgi @ 33632

#!/usr/local/bin/perl
# $Id$
# This program is free software; you can redistribute it and/or # modify it under the same terms as Perl itself
use strict;
use warnings;

Flickr2Twitter->run(YAML::LoadFile('/home/mayuki/.flickr2twitter.yaml'));


package Flickr2Twitter;
use YAML;
use XMLRPC::Transport::HTTP;

use base qw/Class::Data::Inheritable/;

sub authenticate {
    my ($class, $username, $password) = @_;

    $username eq $class->config->{FromFlickr}->{Username} && $password eq $class->config->{FromFlickr}->{Password};
}

sub run {
    my ($class, $config) = @_;

    $class->mk_classdata('config');
    $class->config($config);

    my $server = XMLRPC::Transport::HTTP::CGI
                 -> dispatch_to('blogger', 'metaWeblog')
                 -> handle;

}


package blogger;
sub getUsersBlogs {
    my ($class, $appkey, $username, $password) = @_;

    return undef unless Flickr2Twitter->authenticate($username, $password);

    [{
        url      => 'http://twitter.com/'.Flickr2Twitter->config->{Twitter}->{Username},
        blogid   => '1',
        blogName => 'Twitter - '.Flickr2Twitter->config->{Twitter}->{Username}
    }]
}


package metaWeblog;
use Encode;
use Net::Twitter;

sub newPost {
    my ($class, $blogid, $username, $password, $params, $publish) = @_;

    return undef unless Flickr2Twitter->authenticate($username, $password);

    my $twit = Net::Twitter->new(username => Flickr2Twitter->config->{Twitter}->{Username},
                                 password => Flickr2Twitter->config->{Twitter}->{Password});

    $twit->update(Encode::encode('utf8', $params->{'description'}));

    1;
}