root/lang/perl/Google-Chart-DBIC/trunk/lib/Google/Chart/DBIC.pm @ 17500

package Google::Chart::DBIC;
use Moose;
use Google::Chart ();
use Data::Dumper ();
use POSIX ();
use Scalar::Util ();
our $VERSION = '0.01';

has 'size' => (
    is => 'rw',
    required => 1,
    default => '400x400',
);

has 'type' => (
    is => 'rw',
    required => 1,
    default => 'line',
);

has 'color' => (
    is => 'rw',
    isa => 'ArrayRef[Str]',
    required => 1,
    default => sub {
        [qw(ff0000 00ff00 0000ff ffff00 ff00ff 00ffff)];
    },
);

has 'resultset' => (
    is => 'rw',
    isa => 'ArrayRef[Object]',
    required => 1,
);

has 'axis_x' => (
    is => 'rw',
    isa => 'Str',
);

has 'max_value' => (
    is => 'rw',
    isa => 'Num',
);

no Moose;

sub as_uri {
    my $self = shift;
    my $dataset = {};
    my $axis_x = [];
    my $max_value = 0;
    for my $row (@{$self->resultset}) {
        if (!defined $self->axis_x && $row->has_column_loaded('axis_x')) {
            my $v = $row->get_column('axis_x');
            push @$axis_x, $v unless grep {$v} @$axis_x;
        }
        for ($row->columns) {
            next unless $row->has_column_loaded($_);
            my $v = $row->$_;
            if (defined $self->axis_x && $_ eq $self->axis_x){
                push @$axis_x, $v unless grep {$v} @$axis_x;
                next;
            }
            next unless Scalar::Util::looks_like_number $v;
            push @{$dataset->{$_}}, Scalar::Util::looks_like_number $v ? $v : undef;
            $max_value = $v if $v >= $max_value;
        }
    }
    $max_value = $self->max_value || $max_value;
    my $chart = Google::Chart->new(
        size => $self->size,
        type => $self->type,
        axis => [
            {
                location => 'x',
                labels   => $axis_x ? $self->_roughen($axis_x, 5) : [],
            },
            {
                location => 'y',
                labels   => [ map { $_ * $max_value } map { 0.2 * $_ } (0 .. 5) ],
            }
        ],
        data => {
            module => 'Extended',
            args => {
                dataset => [values %$dataset],
                max_value => $max_value,
            },
        },
        color => [@{$self->color}[0 .. (scalar values %$dataset) - 1]],
        legend => [keys %$dataset],
    );
    return $chart->as_uri;
}

sub _roughen {
    my ($self, $arr, $count) = @_;

    return $arr if scalar @$arr < ($count - 1);
    my $gap = POSIX::ceil($#{$arr}/ ($count - 1));
    my $ret = [];
    for my $i (0 .. $#{$arr}) {
        push @$ret, ($i % $#{$arr} && $i % $gap) ? '' : $arr->[$i];
    }
    return $ret;
}

1;
__END__

=head1 NAME

Google::Chart::DBIC - glue class for Google::Chart and DIBC

=head1 SYNOPSIS

  use TestApp::Schema;
  use Google::Chart::DBIC;

  my $schema = TestApp::Schema->connect(
      "dbi:SQLite:$dbfile"
  );
  my @list = TestApp::Schema->resultset('Climate')->search({
      place => 'Tokyo',
  }{
      select => ['high','low','month'],
      as => ['high','low','axis_x'],
  });
  my $chart = Google::Chart::DBIC->new({
      resultset => @list,
      size => '300x400',
      type => 'line',
  });
  my $uri = $chart->as_uri;    

  
=head1 DESCRIPTION

Google::Chart::DBIC is glue class for Google::Chart and DBIC.

=head1 METHODS

=head2 new(%args)

Constructor.

=over 4

=item type

will be passed to Google::Chart constructor.

=item size

will be passed to Google::Chart constructor.

=item resultset

'looks_like_number' value in the resultset will be plotted on the chart. 
If there is a column named 'axis_x', it will be assigned as bottom axis of the chart.

=item max_value

specify max_value of the chart. defaults max value of the resultset.

=item color

specify color if you don't like default colors.

=item axis_x

specify column name to use as bottom axis of the chart.

=back

=head2 as_uri

Returns google chart uri.

=head1 AUTHOR

Author E<lt>nobuo.danjou@gmail.comE<gt>

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.

=head1 SEE ALSO

L<Google::Chart>

=cut