root/lang/perl/Google-Chart-DBIC/trunk/t/insert.pl @ 17483

use strict;
use warnings;
use FindBin;
use charnames ':full';
use lib "$FindBin::Bin/lib";
use TestApp::Schema;
use Web::Scraper;
use URI;
use YAML;

my $schema = TestApp::Schema->connect(
    "dbi:SQLite:test.db"
);
my $rs = $schema->resultset('Climate');
$rs->delete_all;

my $cities = scraper {
    process '//th[@bgcolor="#add8e6"]', 'data[]' => sub {
        my $city = shift;
        (my $cityname = $city->as_text) =~ s/\N{IDEOGRAPHIC SPACE}+//g;
        my @citydata = $city->findnodes('../following-sibling::tr[1]/td[@align="right"]/font');
        my @result = ();

        for my $month (0 .. 11) {
            my @data = ();
            for ($citydata[$month]->content_refs_list) {
                next if ref $$_;
                push @data, $$_;
            }

            push @result, {
                place => $cityname,
                month => $month + 1,
                average => $data[0] + 0,
                high => $data[1] + 0,
                low => $data[2] + 0,
                rainfall => $data[3] + 0,
            }
        }
        return @result;
    };
    result 'data';
}->scrape(URI->new('http://www.faminet.co.jp/d_guide/d_gnc/gnc1_3.html'));

warn Dump $cities;
for (@$cities){
    $rs->create($_);
};