root/lang/perl/Google-Chart/branches/moose/lib/Google/Chart.pm @ 16118

# $Id$

package Google::Chart;
use Moose;
use Google::Chart::Axis;
use Google::Chart::Data;
use Google::Chart::Size;
use Google::Chart::Type;
use Google::Chart::Types;
use LWP::UserAgent;
use URI;
use overload
    '""' => \&as_uri,
    fallback => 1,
;
our $USER_AGENT;

use constant BASE_URI => URI->new("http://chart.apis.google.com/chart");

our $VERSION   = '0.00001';
our $AUTHORITY = 'cpan:DMAKI';

has 'type' => (
    is       => 'rw',
    does     => 'Google::Chart::Type',
    coerce   => 1,
    required => 1,
);

has 'data' => (
    is       => 'rw',
    does     => 'Google::Chart::Data',
    coerce   => 1,
    required => 1,
);

has 'size' => (
    is       => 'rw',
    isa      => 'Google::Chart::Size',
    coerce   => 1,
    required => 1,
    lazy     => 1,
    default  => sub { Google::Chart::Size->new( width => 400, height => 300 ) },
);

has 'marker' => (
    is       => 'rw',
    isa      => 'Google::Chart::Marker',
    coerce   => 1,
);

has 'axis' => (
    is       => 'rw',
    isa      => 'Google::Chart::Axis',
    coerce   => 1,
);

has 'ua' => (
    is       => 'rw',
    isa      => 'LWP::UserAgent',
    required => 1,
    lazy     => 1,
    default  => sub { $USER_AGENT ||= LWP::UserAgent->new() }
);

__PACKAGE__->meta->make_immutable;

no Moose;

sub as_uri {
    my $self = shift;

    my %query;
    foreach my $c qw( type data size marker axis ) {
        my $component = $self->$c;
        next unless $component;
        my @params = $component->as_query;
        while (@params) {
            my ($name, $value) = splice(@params, 0, 2);
            next unless length $value;
            $query{$name} = $value;
        }
    }

    # If in case you want to change this for debugging or whatever...
    my $uri = $ENV{GOOGLE_CHART_URI} ? 
        URI->new($ENV{GOOGLE_CHART_URI}) :
        BASE_URI->clone;
    $uri->query_form( %query );
    return $uri;
}

sub render {
    my $self = shift;
    my $response = $self->ua->get($self->as_uri);

    if ($response->is_success) {
        return $response->content;
    } else {
        die $response->status_line;
    }
}

sub render_to_file {
    my ($self, $filename) = @_;

    open my $fh, '>', $filename or die "can't open $filename for writing: $!\n";
    print $fh $self->render;
    close $fh or die "can't close $filename: $!\n";
}

1;

__END__

=head1 NAME

Google::Chart - Interface to Google Charts API

=head1 SYNOPSIS

  use Google::Chart;

  my $chart = Google::Chart->new(
    type => "Bar",
    data => [ 1, 2, 3, 4, 5 ]
  );
  print $chart->as_uri, "\n";
  print $chart->render_to_file( filename => 'filename.png' );

=head1 METHODS

=head2 new(%args)

=over 4

=item type

Specifies the chart type, such as line, bar, pie, etc. If given a string like
'Bar', it will instantiate an instance of Google::Chart::Type::Bar by
invoking argument-less constructor.

If you want to pass parameters to the constructor, either pass in an
already instanstiated object, or pass in a hash, which will be coerced to
the appropriate object

  my $chart = Google::Chart->new(
    type => {
      module => "Bar",
      args   => {
        orientation => "horizontal"
      }
    }
  );

=item size

Specifies the chart size. Strings like "400x300", hash references, or already
instantiated objects can be used:

  my $chart = Google::Chart->new(
    size => "400x300",
  );

  my $chart = Google::Chart->new(
    size => {
      width => 400,
      height => 300
    }
  );

=back

=head2 as_uri()

Returns the URI that represents the chart object.

=head2 render()

Generates the chart image, and returns the contents.

=head2 render_to_file( %args )

Generates the chart, and writes the contents out to the file specified by
`filename' parameter

=cut