root/lang/perl/HTML-AutoForm/trunk/lib/HTML/AutoForm/Field/AnyText.pm @ 25263

package HTML::AutoForm::Field::AnyText;

use strict;
use warnings;
use utf8;

our @ISA;
our %Defaults;

BEGIN {
    @ISA = qw(HTML::AutoForm::Field);
    %Defaults = (
        min_length => undef,
        max_length => undef,
        regexp     => undef,
    );
    Class::Accessor::Lite->mk_accessors(keys %Defaults);
};

sub new {
    my $klass = shift;
    my $self = $klass->SUPER::new(
        %Defaults,
        @_ == 1 ? %{$_[0]} : @_,
    );
    if (my $r = $self->regexp) {
        # special mappings
        if (! ref($r) && $r eq 'email') {
            # from http://www.tt.rim.or.jp/~canada/comp/cgi/tech/mailaddrmatch/
            $self->regexp(qr/^[\x01-\x7F]+@(([-a-z0-9]+\.)*[a-z]+|\[\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3}\])/oi);
        }
    }
    $self;
}

sub render {
    my ($self, $values) = @_;
    return HTML::AutoForm::_build_element(
        'input',
        {
            class => 'autoform_field_' . $self->type,
            %$self,
        },
        {
            type  => $self->type,
            $values && @$values ? (value => $values->[0]) : (),
        },
        \%Defaults,
    );
}

sub validate {
    my ($self, $values) = @_;
    
    return HTML::AutoForm::Error->new(
        message => '不正な入力値です',
        field   => $self,
    ) if @$values >= 2;
    if (@$values == 0 || $values->[0] eq '') {
        # is empty
        return unless $self->required;
        return HTML::AutoForm::Error->new(
            message => $self->label . 'を入力してください',
            field   => $self,
        );
    }
    
    my $value = $values->[0];
    if (my $l = $self->min_length) {
        return HTML::AutoForm::Error->new(
            message => $self->label . 'が短すぎます',
            field   => $self,
        ) if length($value) < $l;
    }
    if (my $l = $self->max_length) {
        return HTML::AutoForm::Error->new(
            message => $self->label . 'が長すぎます',
            field   => $self,
        ) if $l < length $value;
    }
    if (my $r = $self->regexp) {
        return HTML::AutoForm::Error->new(
            message => '無効な' . $self->label . 'です',
            field   => $self,
        ) if $value !~ /$r/;
    }
    
    return;
}

1;