root/lang/perl/Method-Cached/trunk/t/benchmark.pl @ 20638

#!/usr/bin/env perl

use strict;
use warnings;
use FindBin::libs;

use Method::Cached::Manager -domains => {
    'cache-memcached-fast' => {
        storage_class    => 'Cache::Memcached::Fast',
        storage_args     => [
            { servers    => [qw/ 127.0.0.1:11211 /] },
        ],
        key_regularizer  => 'SERIALIZE', # 'LIST',
    },
    'cache-fastmmap'       => {
        storage_class    => 'Cache::FastMmap',
        storage_args     => [
            share_file     => '/tmp/fastmmap.bin',
            unlink_on_exit => 0,
        ],
        key_regularizer  => 'SERIALIZE', # 'LIST',
    },
};

{
    package Dummy;

    use Method::Cached;
    use Attribute::Memoize;

    sub fib {
        my $n = shift;
        return $n if $n < 2;
        fib($n - 1) + fib($n - 2);
    }

    sub fib_memcached : Cached('cache-memcached-fast', 5) {
        my $n = shift;
        return $n if $n < 2;
        fib_memcached($n - 1) + fib_memcached($n - 2);
    }

    sub fib_fastmmap : Cached('cache-fastmmap', 5) {
        my $n = shift;
        return $n if $n < 2;
        fib_fastmmap($n - 1) + fib_fastmmap($n - 2);
    }

    sub fib_memoize : Memoize {
        my $n = shift;
        return $n if $n < 2;
        fib_memoize($n - 1) + fib_memoize($n - 2);
    }
}

package main;

use Benchmark;

my $num = 13;

my ($fib, $mc_fib, $fm_fib, $f_fib, $m_fib);

sub fib    { $fib    = $num; $fib    = Dummy::fib($fib)              }
sub mc_fib { $mc_fib = $num; $mc_fib = Dummy::fib_memcached($mc_fib) }
sub fm_fib { $fm_fib = $num; $fm_fib = Dummy::fib_fastmmap($fm_fib)  }
sub m_fib  { $m_fib  = $num; $m_fib  = Dummy::fib_memoize($m_fib)    }

Benchmark::cmpthese(10000, {
    'fib'               => \&fib,
    'C(Memcached-Fast)' => \&mc_fib,
    'C(FastMmap)'       => \&fm_fib,
    'Memoize'           => \&m_fib,
});