root/lang/perl/Mozilla-Screenshot/trunk/examples/screenshot-httpd-poe.pl @ 114

#!/usr/bin/perl

BEGIN {
    unless ($ENV{DISPLAY}) {
        die q"can't find DISPLAY ($ENV{DISPLAY})";
    }
}

use strict;
use warnings;
use Pod::Usage qw(pod2usage);
use Getopt::Long qw(GetOptions);
use Class::Inspector;
use Socket qw(INADDR_LOOPBACK);
use IO::Poll;
use HTTP::Response;
use HTTP::Status;
use Mozilla::Screenshot;

use POE qw(
    Sugar::Args
    Wheel::SocketFactory
    Wheel::ReadWrite
    Wheel::Run
    Filter::Stream
    Filter::HTTPD
    Component::TSTP
);

GetOptions(
    'h|help'    => sub { pod2usage 1 },
    'p|port=i'  => \ (my $port = 3000),
    'x|proxy=s' => \ my $proxy,
) or pod2usage 1;

$ENV{HTTP_PROXY} = $proxy if $proxy;

POE::Component::TSTP->create;

POE::Session->create(
    inline_states  => {
        _start => sub { sweet_args->kernel->yield('server_start') },
    },
    package_states => [ main => Class::Inspector->methods('main') ],
    heap           => { port => $port },
);

POE::Kernel->sig($_ => sub { POE::Kernel->stop }) for qw( INT TERM HUP );
POE::Kernel->run;
exit;

sub server_start {
    my $poe = sweet_args;

    $poe->heap->{server} = POE::Wheel::SocketFactory->new(
        BindAddress  => INADDR_LOOPBACK,
        BindPort     => $poe->heap->{port},
        SuccessEvent => 'server_accept',
        FailureEvent => 'server_error',
        Reuse        => 'on',
    );

    $poe->heap->{ua} = Mozilla::Screenshot->new({ env_proxy => $ENV{HTTP_PROXY} ? 1 : 0 });
}

sub server_accept {
    my $poe = sweet_args;

    my $connection = POE::Wheel::ReadWrite->new(
        Handle       => $poe->args->[0],
        InputEvent   => 'client_input',
        FlushedEvent => 'client_flush',
        ErrorEvent   => 'client_error',
        Filter       => POE::Filter::HTTPD->new,
    );

    $poe->heap->{connection}->{$connection->ID} = $connection;
}

sub server_error { delete sweet_args->heap->{server} }

sub client_input {
    my $poe = sweet_args;
    my $req = $poe->args->[0];

    my $res = HTTP::Response->new;
    $res->protocol('HTTP/1.0');
    $res->request($req);
    $res->date(time);
    $res->header(Connection => 'close');

    if (my $uri = $req->header('Content-Location')) {
        my $image;
        eval { $image = $poe->heap->{ua}->fetch($uri)->save_to_buffer('png') };
        $@ ? $res->code(RC_INTERNAL_SERVER_ERROR) : do {
            $res->code(RC_OK);
            $res->content_type('image/png');
            $res->content_length(length $image);
            $res->content($image);
        };
    }
    else {
        $res->code(RC_BAD_REQUEST);
    }

    $poe->heap->{connection}->{$poe->args->[1]}->put($res);
}

sub client_flush {
    my $poe = sweet_args;
    $poe->kernel->yield(client_close => $poe->args->[0]);
}

sub client_close {
    my $poe = sweet_args;
    delete $poe->heap->{connection}->{$poe->args->[0]};
}

sub client_error {
    my $poe = sweet_args;
    $poe->kernel->yield(client_close => $poe->args->[3]);
}

__END__

=head1 NAME

screenshot-httpd-poe.pl - sample screenshot httpd with POE

=head1 SYNOPSIS

screenshot-httpd-poe.pl [options]

 Options:
   -h --help      display this help and exits
   -p --port      port (defaults to 3000)
   -x --proxy     proxy (defaults to $ENV{HTTP_PROXY})

=cut