root/lang/perl/Mvalve/trunk/t/03_extended.t @ 15353

use strict;
use Test::More;

BEGIN
{
    eval { require Cache::Memcached };
    if ($@) {
        plan(skip_all => "Cache::Memcached not installed");
    } elsif (! $ENV{MVALVE_Q4M_DSN} ) {
        plan(skip_all => "Define MVALVE_Q4M_DSN to run this test");
    } else {
        plan(tests => 47);
    }

    $ENV{MEMCACHED_SERVERS} ||= '127.0.0.1:11211';
    $ENV{MEMCAHCED_NAMESPACE} ||= join('_', __FILE__, $$, {}, rand());
    $ENV{MEMCACHED_SERVERS} = [
        split(/\s*,\s*/, $ENV{MEMCACHED_SERVERS}) ];

    use_ok("Mvalve");
}

can_ok( "Mvalve" => qw(
    next fallback next_retry retry
) );

{
    my $mvalve = Mvalve->new(
        timeout   => 1,
        queue => {
            connect_info => [ 
                $ENV{MVALVE_Q4M_DSN},
                $ENV{MVALVE_Q4M_USERNAME},
                $ENV{MVALVE_Q4M_PASSWORD},
                { RaiseError => 1, AutoCommit => 1 },
            ]
        },
        throttler => {
            module    => 'Data::Throttler::Memcached',
            max_items => 1,
            interval  => 10,
            cache     => {
                data => $ENV{MEMCACHED_SERVERS},
                namespace => $ENV{MEMCACHED_NAMESPACE},
            },
        },
        state => {
            module => 'Mvalve::State::Memcached',
            servers => $ENV{MEMCACHED_SERVERS},
            namespace => $ENV{MEMCACHED_NAMESPACE},
        }
    );
    $mvalve->clear_all;

    ok( $mvalve );
    isa_ok( $mvalve, "Mvalve" );

    my $count = 32;

    diag( "Generating $count messages...." );
    for my $i (1..$count) {
        my $message = Mvalve::Message->new(
            headers => {
                'X-Mvalve-Destination' => 'test'
            },
            content => $i,
        );
        $mvalve->insert( message => $message );
    }

    {
        my $message = $mvalve->next;
        isa_ok( $message, 'Mvalve::Message', 'first message should not be throttled' );

        $count--;
        for my $i (1..$count) {
            my $message = $mvalve->next;
            is( $message, undef, "subsequent messages should be throttled" );
        }
    }

    {
        my $i = 0;
        while ($i < $count) {
            my $rv = $mvalve->next_retry;
            $i++ if $rv;
        }
        is( $i, $count );
    }
}