root/lang/perl/Okina/trunk/okina-starter @ 10464

#!/usr/bin/perl

use strict;
use warnings;
use ExtUtils::MakeMaker qw(prompt);
use File::Basename;
use File::Path;
use File::Spec;
use Template;
use YAML;
use Config::Pit;

my $config = pit_get(
    'pmsetup',
    require => {
        author        => 'Tokuhiro Matsuno',
        email         => 'tokuhirom AAJKLFJEF GMAIL COM',
    }
);

my $modname = shift @ARGV or die "Usage: $0 module\n";
   $modname =~ s/-/::/g;

write_plugin_files($modname, $config);

sub write_plugin_files {
    my($module, $config) = @_;

    my $coderepos = prompt("CodeRepos friendly? [Yn] ", 'y');

    # $module = "Foo::Bar"
    # $dist   = "Foo-Bar"
    # $path   = "Foo/Bar.pm"
    my @pkg  = split /::/, $module;
    my $dist = join "-", @pkg;
    my $path = join("/", @pkg) . ".pm";

    mkdir $dist, 0777;
    chdir $dist;

    my @template = YAML::Load(join '', <DATA>);
    my $vars = { module => $module, dist => $dist, path => $path,
                 config => $config, localtime => scalar localtime };

    for my $tmpl (@template) {
        my $file = $tmpl->{file};
           $file =~ s/(\$\w+)/$1/eeg;
        if (defined $tmpl->{coderepos}) {
            if ($coderepos =~ /[Yy]/) {
                next unless $tmpl->{coderepos};
            } else {
                next if $tmpl->{coderepos};
            }
        }
        write_file($file, $tmpl->{template}, $vars);
        chmod oct($tmpl->{chmod}), $tmpl->{file} if $tmpl->{chmod};
    }

    !system "perl Makefile.PL" or die $?;
    !system 'make test' or die $?;
    !system 'make manifest' or die $?;
    !system 'make distclean' or die $?;
}

sub write_file {
    my($path, $template, $vars) = @_;

    if (-e $path) {
        my $ans = prompt("$path exists. Override? [yN] ", 'n');
        return if $ans !~ /[Yy]/;
    }

    my $dir = File::Basename::dirname($path);
    unless (-e $dir) {
        warn "Creating directory $dir\n";
        File::Path::mkpath($dir, 1, 0777);
    }

    my $tt = Template->new;
    $tt->process(\$template, $vars, \my $content);

    warn "Creating $path\n";
    open my $out, ">", $path or die "$path: $!";
    print $out $content;
    close $out;
}

=pod

original L<http://svn.bulknews.net/repos/public/misc/pmsetup>

=cut

__DATA__
---
file: Makefile.PL
template: |
  use inc::Module::Install;
  name '[% dist %]';
  all_from 'lib/[% path %]';

  requires $_ for (qw/
  /);

  build_requires 'Test::More';
  build_requires 'YAML';
  use_test_base;
  auto_include;
  WriteAll;
---
file: t/00_compile.t
template: |
  use strict;
  use Test::More tests => 1;

  BEGIN { use_ok '[% module %]' }
---
file: t/97_podspell.t
template: |
  use Test::More;
  eval q{ use Test::Spelling };
  plan skip_all => "Test::Spelling is not installed." if $@;
  add_stopwords(map { split /[\s\:\-]/ } <DATA>);
  $ENV{LANG} = 'C';
  all_pod_files_spelling_ok('lib');
  __DATA__
  [% config.author %]
  [% module %]
  tokuhirom
  AAJKLFJEF
  GMAIL
  COM
  Tatsuhiko
  Miyagawa
---
file: t/98_perlcritic.t
template: |
  use strict;
  use Test::More;
  eval { use Test::Perl::Critic -profile => 't/perlcriticrc' };
  plan skip_all => "Test::Perl::Critic is not installed." if $@;
  all_critic_ok('lib');
---
file: t/99_pod.t
template: |
  use Test::More;
  eval "use Test::Pod 1.00";
  plan skip_all => "Test::Pod 1.00 required for testing POD" if $@;
  all_pod_files_ok();
---
file: t/perlcriticrc
template: |
  [TestingAndDebugging::ProhibitNoStrict]
  allow=refs
---
file: script/$dist-server.pl
template: |
  use strict;
  use warnings;
  use FindBin;
  use File::Spec::Functions;
  use lib catfile($FindBin::Bin, 'lib');
  use HTTP::Engine;
  use [% module %];

  HTTP::Engine->new(
      config         => [% module %]->conf->{engine},
      handle_request => \&_handle_request,
  )->run;

  sub _handle_request {
        my $c = shift;
        [% module %]->handle_request( $c );
  }
---
file: lib/$path
template: |
  package [% module %];
  use strict;
  use warnings;
  use 5.00800;
  our $VERSION = '0.01';
  use UNIVERSAL::require;
  use [% module %]::Dispatcher;
  use [% module %]::Config;
  use Okina;

  1;
---
file: lib/$dist/Dispatcher.pm
template: |
  package [% module %]::Dispatcher;
  use strict;
  use warnings;
  use HTTPx::Dispatcher;

  connect '' => { controller => 'Root', action => 'index' };

  1;
---
file: lib/$dist/Config.pm
template: |
  package [% module %]::Config;
  use strict;
  use warnings;
  use Okina::Config;
  
  1;
---
file: lib/$dist/C/Root.pm
template: |
  package [% module %]::C::Root;
  use strict;
  use warnings;
  use Okina::Controller;

  sub index :Private {
     my $c = shift;
     $c->res->body('Okina!');
  }

  1;
---
file: MANIFEST.SKIP
template: |
  \bRCS\b
  \bCVS\b
  ^MANIFEST\.
  ^Makefile$
  ~$
  ^#
  \.old$
  ^blib/
  ^pm_to_blib
  ^MakeMaker-\d
  \.gz$
  \.cvsignore
  ^t/9\d_.*\.t
  ^t/perlcritic
  ^tools/
  \.svn/
  ^[^/]+\.yaml$
  ^[^/]+\.pl$
  ^\.shipit$
  \.sw[po]$
---
file: README
template: |
  This is Perl module [% module %].

  INSTALLATION

  [% module %] installation is straightforward. If your CPAN shell is set up,
  you should just be able to do

      % cpan [% module %]

  Download it, unpack it, then build it as per the usual:

      % perl Makefile.PL
      % make && make test

  Then install it:

      % make install

  DOCUMENTATION

  [% module %] documentation is available as in POD. So you can do:

      % perldoc [% module %]

  to read the documentation online with your favorite pager.

  [% config.author %]
---
file: .shipit
chmod: 0644
coderepos: 0
template: |
  steps = FindVersion, ChangeVersion, CheckChangeLog, DistTest, Commit, Tag, MakeDist, UploadCPAN
  svk.tagpattern = release-%v
---
file: .shipit
chmod: 0644
coderepos: 1
template: |
  steps = CommitMessageWrap, FindVersion, ChangeVersion, CheckChangeLog, DistTest, Commit, Tag, MakeDist, UploadCPAN
  svk.tagpattern = release-%v
  commit_message.format = lang/perl/[% dist %]: %msg
---
file: config.yaml
template: |
  ---
  engine:
    plugins:
      - module: Interface::Standalone
        conf:
          host: 0.0.0.0
          port: 14000