root/lang/perl/Senna/trunk/lib/Senna/Index.pm @ 3915

# $Id$
#
# Copyright (c) 2007 Daisuke Maki <daisuke@endeworks.jp>
# All rights reserved.

package Senna::Index;
use strict;
use warnings;
use Senna::Index::Info;
use Senna::Record;

sub create
{
    my $class = shift;
    my %args  = @_;

    my @xs_args = map { $args{$_} }
        qw(path key_size flags initial_n_segments encoding);
    pop @xs_args while @xs_args && ! defined $xs_args[-1];
    $class->XS_create(@xs_args);
}

sub open
{
    my $class = shift;
    if (@_ == 1) {
        if(ref $_[0] eq 'HASH') {
            @_ = ($_[0]->{path});
        }
    } elsif (@_ > 1) {
        my %args  = @_;
        @_ = ($args{path});
    }

    $class->_XS_open(@_);
}

sub info
{
    my $self = shift;
    if ( wantarray ) {
        return $self->XS_info();
    } else {
        my %h;
        my @fields = qw(key_size flags initial_n_segments encoding nrecords_keys file_size_keys nrecords_lexicon file_size_lexicon inv_seg_size inv_chunk_size);
        @h{ @fields } = $self->XS_info();

        return Senna::Index::Info->new(%h);
    }
}

sub insert
{
    my $self = shift;
    if (@_ == 1 && ref $_[0] eq 'HASH') {
        @_ = ($_[0]->{key}, $_[0]->{value});
    } elsif (@_ > 2) {
        my %args = @_;
        @_ = ($args{key}, $args{value});
    }
    $self->_XS_insert(@_);
}

sub select
{
    my $self = shift;
    if (@_ == 1 && ref $_[0] eq 'HASH') {
        @_ = map { $_[0]->{$_} } qw(query records op optarg);
    } elsif (@_ > 1) {
        my %args = @_;
        @_ = @args{qw(query records op optarg)};
    }

    $self->_XS_select(@_);
}

1;

__END__

=head1 NAME

Senna::Index - Senna Index Object

=head1 SYNOPSIS

  use Senna;

  my $index = Senna::Index->create();
  my $index = Senna::Index->open($path);

  $index->insert($key, $value);
  $index->select($query);

=head1 METHODS

=head2 create

=head2 open

Opens an existing index.

  my $index = Senna::Index->open($path);
  my $index = Senna::Index->open({ path => $path });

For backwards compatibility, if given more than one argument, open() assumes
that you've been given a key value pair like so:

  my $index = Senna::Index->open(path => $path);

However, note that this form is DEPRECATED. Use the HASHREF form instead

=head2 info

In scalar context, returns a Senna::Index::Info object.

  $info = $index->info;
  $info->key_size();

In list context, returns the same informtion as a list:

  ($key_size, $flags, $initial_n_segments, $encoding, $nrecords_keys,
    $file_size_keys, $nrecords_lexicon, $file_size_lexicon, $inv_seg_size,
      $inv_chunk_size) = $index->info

=head2 path

Returns the path to the senna index.

=head2 close

=head2 remove

=head2 update

=head2 insert

Inserts a new entry in the index.

  $index->insert($key, $value);
  $index->insert({ key => $key, value => $value });

For backwards compatibility if given more than 2 arguments, insert() assumes 
that you've been given a key/value pair like so:

  $index->insert(key => $key, value => $value);

However, note that this form is DEPRECATED. Use the HASHREF form instead

=cut