root/lang/perl/WebService-YahooJP-TextParse/trunk/lib/WebService/YahooJP/TextParse.pm @ 7090

package WebService::YahooJP::TextParse;

use strict;
use warnings;

our $VERSION = '0.01';

use Array::Iterator::BiDirectional;
use Encode;
use LWP::UserAgent;
use XML::Simple;

sub new {
    my ($class, %opt) = @_;

    my $self = bless {
        url => 'http://api.jlp.yahoo.co.jp/MAService/V1/parse',
        %opt,
    }, $class;

    $self->init;
    $self;
}

sub init {
    my $self = shift;

    my $ua = LWP::UserAgent->new;
    $ua->timeout($self->{timeout} || 3);
    $ua->env_proxy;
    $self->{ua} = $ua;
}

sub analysis {
    my ($self, $content) = @_;

    $content = Encode::encode('utf-8', $content) if utf8::is_utf8($content);

    my %form = (
        appid => $self->{appid},
        results => 'ma',
        sentence => $content,
    );

    my $res = $self->{ua}->post( $self->{url}, \%form );

    $XML::Simple::PREFERRED_PARSER = 'XML::Parser';
    my $parser = XML::Simple->new;
    $self->{result} = $parser->XMLin($res->content);
    $self->{word} = $self->{result}->{ma_result}->{word_list}->{word};
    $self->{word} = [ $self->{word} ] if ref($self->{word}) and ref($self->{word}) eq 'HASH';
    @{ $self->{word} } = grep { ref($_->{surface}) ne 'HASH' } @{ $self->{word} };

    return wantarray ? @{ $self->{word} } : Array::Iterator::BiDirectional->new($self->{word});
}

1;
__END__

=head1 NAME

WebService::YahooJP::TextParse - Perl interface to Japanese language morphological analysis of Yahoo! JAPAN

=head1 SYNOPSIS

  use WebService::YahooJP::TextParse;
  
  my $config = { appid => "your-app-id" };
  my $ma = WebService::YahooJP::TextParse->new(%$config);
  my $text = "some japanese sentense";
  my $iter = $ma->analysis($text);
  # $iter is an Array::Iterator::BiDirectional object.
  while ($iter->hasNext) {
      my $word = $iter->getNext();
      next if ref($word->{surface}) eq 'HASH';
  
      print Dump $word;
  }

=head1 DESCRIPTION

This is a Perl interface to Japanese language morphological analysis of Yahoo! JAPAN.
See Developers Page L<http://developer.yahoo.co.jp/jlp/MAService/V1/parse.html> for details.

=head1 AUTHOR

woremacx E<lt>woremacx at cpan dot orgE<gt>

=head1 LICENSE

This library is free software; you can redistribute it and/or modify
it under the same terms as Perl itself.

=head1 SEE ALSO

L<Array::Iterator::BiDirectional>

=cut