root/lang/perl/XML-FromHTML/trunk/lib/XML/FromHTML.pm

#
# $Id$
#
package XML::FromHTML;
use warnings;
use strict;
our $VERSION = sprintf "%d.%02d", q$Revision: 0.2 $ =~ /(\d+)/g;

use base 'Exporter';
our @EXPORT = qw/html2xml/;

use base 'HTML::Tidy';

sub new {
    my $class = shift;
    bless HTML::Tidy->new(
        {
            @_,
            doctype          => 'omit', # important for speed!
            indent           => 0,
            numeric_entities => 1,
            output_xhtml     => 1,
            tidy_mark        => 0,
            wrap             => 0,
        }
    ), $class;
}

sub html2xml {
    my ($src, $enc) = @_;
    if ($enc){
        require Encode;
        Encode::from_to($src, $enc, 'utf8');
    }
    __PACKAGE__->new->clean($src) 
}

if ($0 eq __FILE__){
    warn html2xml(qq{<a href="http://www.dan.co.jp/">Dan Kogai</a>})
}

1; # End of XML::FromHTML

=head1 NAME

XML::FromHTML - Converts HTML to XHTML

=head1 VERSION

$Id$

=head1 SYNOPSIS

  use XML::FromHTML;
  my $xhtml = XML::FromHTML->new->clean($html);
  # or simply
  my $xhtml = html2xml($html);
  use XML::Simple;
  my $obj = XMLin $xhtml;                           # works fine!
  use XML::LibXML;
  my $dom = XML::LibXML->new->parse_string($xhtml); # this, too!

=head1 DESCRIPTION

This module uses L<HTML::Tidy> just to turn HTML into XML.  T/O.

=head1 EXPORT

C<html2xml> by default.

=head1 FUNCTIONS

=head2 new

Creates an XML::FromHTML object, whose parent class is L<HTML::Tidy>.

=head2 html2xml

just a shortcut for:

  XML::FromHTML->new->clean(shift);

=head1 AUTHOR

Dan Kogai, C<< <dankogai at dan.co.jp> >>

=head1 BUGS

Please report any bugs or feature requests to C<bug-xml-fromhtml at rt.cpan.org>, or through
the web interface at L<http://rt.cpan.org/NoAuth/ReportBug.html?Queue=XML-FromHTML>.  I will be notified, and then you'll
automatically be notified of progress on your bug as I make changes.

=head1 SUPPORT

You can find documentation for this module with the perldoc command.

    perldoc XML::FromHTML

You can also look for information at:

=over 4

=item * RT: CPAN's request tracker

L<http://rt.cpan.org/NoAuth/Bugs.html?Dist=XML-FromHTML>

=item * AnnoCPAN: Annotated CPAN documentation

L<http://annocpan.org/dist/XML-FromHTML>

=item * CPAN Ratings

L<http://cpanratings.perl.org/d/XML-FromHTML>

=item * Search CPAN

L<http://search.cpan.org/dist/XML-FromHTML/>

=back

=head1 ACKNOWLEDGEMENTS

L<HTML::Tidy>, L<XML::Liberal>

=head1 COPYRIGHT & LICENSE

Copyright 2009 Dan Kogai, all rights reserved.

This program is free software; you can redistribute it and/or modify it
under the same terms as Perl itself.


=cut