root/lang/perl/XMPP-Bomber/trunk/script/xmpp-bomber @ 13192

#!/usr/local/bin/perl
use strict;
use File::Spec;
use Getopt::Long;
use XMPP::Bomber;

my @caller = caller();
main() if (!@caller || $caller[0] eq 'PAR');

sub main
{
    my %opts;
    my @opts = qw(
        config=s
        username=s
        password=s
        domain=s
        help!
    );

    if (! GetOptions(\%opts, @opts)) {
        exit 1;
    }

    if ($opts{help}) {
        require Pod::Usage;
        Pod::Usage::pod2usage(2);
    }

    # Read the config, if any
    my $config = {};
    my $config_file = $opts{config} ||
        File::Spec->catfile((getpwuid($>))[7], '.xmppbomberrc');
    if (-f $config_file) {
        require Config::Any;
        my $list = Config::Any->load_files({
            files => [ $config_file ],
            use_ext => 1,
        });
        $config = $list->[0]->{ $config_file } or die;
    }
    $config = { %$config, %opts };

    my $bomber = XMPP::Bomber->new(%$config);
    $bomber->run;
}

1;

__END__

=head1 NAME

xmpp-bomber - Front End To XMPP::Bomber

=head1 SYNOPSIS

  xmpp-bomber [ --config=config.yaml ]

=cut