root/lang/perl/blosxom/plugins/datesection @ 23757

# Blosxom Plugin:   datesection
# Author:           Naoki Okamura (Nyarla) <thotep@nyarla.net>
# Version:          2008-03-02
# License:          public domain

package datesection;

use strict;
use warnings;

use CGI qw( path_info );
use FileHandle;

# -- package variables --------------- #

our %section         = ();

my @index2section   = ();
my %section2index   = ();
my %section2path    = ();

my $datekey         = q{};
my $fh              = FileHandle->new;

our (
    $number, $section, $filename,
    $title, $body,
    $is_permalink,
    $next_path, $prev_path, $next_title, $prev_title
);

# ------------------------------------ #

sub start {
    if ( $blosxom::path_info_da ne q{} ) {
        my $path        = path_info();
        my $datepath    = join q{/}, ( $blosxom::path_info_yr, $blosxom::path_info_mo, $blosxom::path_info_da );
        if ( $path =~ m{$datepath/(\d+)(?:\.(.+?))?$} ) {
            $section        = $1;
            $datekey        = join q{-}, ( $blosxom::path_info_yr, $blosxom::path_info_mo_num, $blosxom::path_info_da );
            $is_permalink   = 1;
            $blosxom::flavour   = $2 if ( $2 ne q{} );
            $blosxom::path_info =~ s{$section\.(.+?)$}{};
        }
    }
    return 1;
}

sub filter {
    my ( $class, $files, $others ) = @_;

    my $entries = {};
    for my $path ( sort { $files->{$a} <=> $files->{$b} } keys %{ $files } ) {
        my $key = join q{-}, (blosxom::nice_date( $files->{$path} ))[5,2,3];
        $entries->{$key} = [] if ( ref $entries->{$key} ne 'ARRAY' );
        push @{ $entries->{$key} }, $path;
    }

    for my $date ( keys %{ $entries } ) {
        my $stories = $entries->{$date};
        for ( my $i = 0; $i < @{ $stories }; $i++ ) {
            my $path = $stories->[$i];
            $section{$path} = {
                date    => $date,
                section => $i + 1,
            };
            my $sectionkey = "${date}-" . ($i + 1);
            push @index2section, $sectionkey;
            $section2path{$sectionkey} = $path;
        }
    }

    @index2section  = sort { $b cmp $a } @index2section;
    %section2index  = map { $index2section[$_] => $_ } 0 .. $#index2section;

    if ( $section ) {
        ( $filename ) = grep {
            my $data = $section{$_};
            $data->{'date'} eq $datekey && $data->{'section'} eq $section
        } keys %section;
        my $mtime    = $files->{$filename};
        %{ $files }  = ( $filename => $mtime );
        ( $title, $body ) = get_data( $filename );
    }


    return 1;
}

sub head {
    my ( $class, $path, $head_ref ) = @_;

    if ( $is_permalink ) {
        my $key     = "${datekey}-${section}";
        my $index   = $section2index{$key};

        if ( $index < $#index2section ) {
            $prev_path = $index2section[ $index + 1 ];
            $prev_path =~ s{[-]}{/}g;
            $prev_title = ( get_data( $section2path{ $index2section[ $index + 1 ] } ) )[0];
        }

        if ( $index > 0 ) {
            $next_path = $index2section[ $index - 1 ];
            $next_path =~ s{[-]}{/}g;
            $next_title = ( get_data( $section2path{ $index2section[ $index - 1 ] }  ) )[0]
        }
    }

}

sub story {
    my ( $class, $path, $fn, $story_ref, $title_ref, $body_ref ) = @_;
    my $key = "$blosxom::datadir$path/$fn.$blosxom::file_extension";
    $number = $section{$key}->{'section'};
    return 1;
}

sub get_data {
    my ( $file ) = @_;

    my ( $title, $body );

    if ( -f $file && $fh->open( $file, '<' ) ) {
        chomp( $title = <$fh> );
        $body = do { local $/; <$fh> };
        $fh->close;
    }

    return ( $title, $body );
}

1;