root/lang/perl/irssi/scripts/dopplr.pl

use strict;
use warnings;

use Irssi;
use POSIX ();

use Net::Dopplr;

use DateTime;
use DateTime::Format::W3CDTF;

our $VERSION = '0.01';

our %IRSSI = (
    name        => 'dopplr',
    description => 'show local time of dopplr user',
    authors     => 'Daisuke Murase',
);

sub clock {
    my ($nick) = @_;

    my $token = Irssi::settings_get_str('dopplr_token');
    unless ($token) {
        Irssi::print("auth token is required");
        return;
    }

    unless ($nick) {
        Irssi::print("nick not given");
        return;
    }

    my ($rh, $wh);
    pipe $rh, $wh;

    my $pid = fork;
    if ($pid) {
        close $wh;
        Irssi::pidwait_add($pid);

        my $target = { fh => $rh };
        $target->{tag} = Irssi::input_add( fileno($rh), INPUT_READ, \&pipe_input, $target );
    }
    elsif (defined $pid) {
        close $rh;

        my $d    = Net::Dopplr->new($token);
        my $info = $d->traveller_info($nick);

        if ($info->{error}) {
            eval {
                print $wh $info->{error};
                close $wh;
            };
        }
        else {
            my $status = $info->{traveller}{status};
            my $time   = $info->{traveller}{current_city}{localtime};

            my $dt = DateTime::Format::W3CDTF->new->parse_datetime($time);

            eval {
                print $wh "$nick $status (" . $dt->strftime('%m/%d %H:%M') . ")";
                close $wh;
            };
        }

        POSIX::_exit(1);
    }
}

sub pipe_input {
    my $target = shift;

    my ($tag, $rh) = @$target{qw/tag fh/};

    my $res = <$rh>;
    close $rh;

    Irssi::input_remove($tag);
    Irssi::active_win->print($res);
}

Irssi::command_bind( clock => \&clock );
Irssi::settings_add_str( 'dopplr', 'dopplr_token', '' );