root/lang/perl/misc/early-hatena-bookmarkers/early-hatena-bookmarkers.pl

#!/usr/bin/perl

use strict;
use warnings;
use utf8; # but maybe no need ;-D

use XML::Feed;
use URI;

# ID
our $ID    = $ARGV[0] || 'bayashi_net';

# 定数
our $LIMIT = 100; # 結果表示するユーザ数の最大数
our $PAGE  = 4;   # 実際に処理するページ - 1 の値
our $ROW   = 20;  # 1ページあたりのブックマーク数
our $SLEEP = 3;   # ウェイト秒


#--- メインルーチン
{

    # 集計するブックマークIDのチェック
    if ( $ID !~ /^[a-zA-Z][-a-zA-Z0-9_]{1,30}[a-zA-Z0-9]$/ ) {
        die "ID [$ID] is wrong!";
    }

    print "[$ID]\n";

    # 集計
    my %users = get_commenters( $ID, get_my_bookmarks( get_my_rss($ID) ) );

    # 結果表示
    my $count = 1;
    for my $user ( sort { $users{$b} <=> $users{$a} } keys %users ) {

        printf "%03d : %03d : %15s : http://b.hatena.ne.jp/%s/\n",
                $count, $users{$user}, $user, $user;

        last if $LIMIT < ++$count;

    }

}


#--- 以下、サブルーチン

# idのブックマークRSSページのURLをリストで返します
sub get_my_rss {
    my $id = shift;

    my @my_rss;
    for my $p (0..$PAGE) {

        my $of = $p * $ROW + ($p==0);
        push @my_rss, "http://b.hatena.ne.jp/$id/rss?of=$of";

    }

    return @my_rss;
}

# RSSページからブックマークしたエントリーURLをリストで返します
sub get_my_bookmarks {
    my @my_rss = @_;

    my @my_bookmarks;
    for my $rss_url (@my_rss) {

        my $feed = XML::Feed->parse( URI->new($rss_url) )
                    or die XML::Feed->errstr. "\nCan not parse [$rss_url].\n";

        for my $item ($feed->entries) {
            push @my_bookmarks, 'http://b.hatena.ne.jp/entry/rss/'. $item->link;
        }

        sleep $SLEEP;

    }

    return @my_bookmarks;
}

# 各ブックマークページのブックマーカーから
# 自分($id)よりも早くブックマークしているユーザをハッシュでカウントします
sub get_commenters {
    my ($id, @bookmarks) = @_;

    my %users;
    for my $url (@bookmarks) {

        my $rss = XML::Feed->parse( URI->new($url) )
                        or die XML::Feed->errstr. "\nCan not parse [$url].\n";

        my $me = 0;
        for my $item ($rss->entries) {

            my $link = $item->link;
            next unless $link;

            if ($me) {
                $users{$1}++ if $link =~ m!^http://b\.hatena\.ne\.jp/([^/]+)/!;
            }
            elsif ( $link =~ m!^http://b\.hatena\.ne\.jp/\Q$id\E/! ) {
                $me = 1;
            }

        }
        sleep $SLEEP;
    }
    return %users;
}


__END__


=head1 NAME

    early-hatena-bookmarkers.pl - お気に入りをふやそう！

=head1 DESCRIPTION

    このスクリプトは、あるIDがブックマークしているエントリーを
    IDよりも早くブックマークしているユーザを集計表示します。

=head1 SYNOPSIS

    # perl early-hatena-bookmarkers.pl HATENA_ID

=head1 SEE ALSO

    http://b.hatena.ne.jp/

=head1 AUTHOR

    id:bayashi_net

=head1 LICENSE

    This module is free software; you can redistribute it and/or
    modify it under the same terms as Perl itself. See L<perlartistic>.

=cut