root/lang/perl/misc/todo-pl-wassr/wassr-todo.pl @ 528

#!/usr/bin/perl
use strict;
use warnings;
use LWP::UserAgent;
use autobox;
use autobox::Core;

# -------------------------------------------------------------------------

package Net::Wassr::TODO;

use JSON::Syck;
use Carp;

our $VERSION = 0.01;
our $BASE_URL = 'http://api.wassr.jp/todo';
our $APIHOST  = 'api.wassr.jp:80';
our $APIREALM = 'API Authentication';

sub new {
    my $class = shift;
    my $args = shift;

    croak "username missing" unless $args->{username};
    croak "password missing" unless $args->{password};

    my $ua = LWP::UserAgent->new(agent => __PACKAGE__."/".$VERSION);
    $ua->env_proxy;
    $ua->credentials(
        $APIHOST,  $APIREALM,
        $args->{username}, $args->{password}
    );

    bless {ua => $ua}, $class;
}

sub list {
    my ($self, ) = @_;

    my $ret = [];
    my $page = 1;
    while (1) {
        my $res = $self->{ua}->get("$BASE_URL/list.json?page=$page");
        if ($res->is_success) {
            my $dat = JSON::Syck::Load($res->content);
            if ($dat->size()) {
                $ret->push( @$dat );
            } else {
                return $ret;
            }
        } else {
            croak $res->status_line;
        }

        $page++;
    }
}

sub done {
    my ($self, $todo_rid) = @_;

    my $res = $self->{ua}->post("$BASE_URL/done.json", [todo_rid => $todo_rid]);
    if ($res->is_success) {
        return $res->content;
    } else {
        croak $res->status_line;
    }
}

sub add {
    my ($self, $body) = @_;

    my $res = $self->{ua}->post("$BASE_URL/add.json", [body => $body]);
    if ($res->is_success) {
        return $res->content;
    } else {
        croak $res->status_line;
    }
}

package main;
use strict;
use warnings;
use Switch;
use YAML::Syck;
use IO::File;
use IO::Prompt;

our $CONFFILE = "$ENV{HOME}/.wassr-todo";

sub main {
    my $command = shift @ARGV || 'list';

    my $conf;
    if ( -e $CONFFILE ) {
        $conf = YAML::Syck::LoadFile($CONFFILE);
    } else {
        $conf->{username} = prompt 'username:';
        $conf->{password} = prompt 'password:', -echo => '*';
        YAML::Syck::DumpFile($CONFFILE => $conf);
    }

    my $c = Net::Wassr::TODO->new($conf);

    switch ($command) {
        case 'list' {
            my $list = $c->list;

            print $list->map(sub {
                $_[0]->{todo_rid} . ' ' . $_[0]->{body}
            })->join("\n");
            print "\n";
        }
        case 'done' {
            my $todo_rid = shift @ARGV;
            die "TODO rid missing for $command" unless $todo_rid;
            print $c->done($todo_rid), "\n";
        }
        case 'bd' {
            # braindump
            require File::Temp;

            my $editor = $ENV{EDITOR};
            die "\$ENV{EDITOR} missing" unless $editor;

            my $fh = File::Temp->new(UNLINK => 0);
            my $fn = $fh->filename;
            $fh->close;

            system $editor, $fn;
            upload_textfile( $c, $fn );
            unlink $fn;
        }
        else {
            die "unknown command $command";
        }
    }
}

sub upload_textfile {
    my ($c, $fname) = @_;

    my $fh = IO::File->new($fname, 'r');
    while (<$fh>) {
        s/[\r\n]//g;
        my $line = $_;

        $c->add( $line );
    }
}

&main();