root/lang/perl/plagger/assets/plugins/CustomFeed-Script/www_nhk_or_jp_gogaku_english_business1.pl

#!/usr/bin/env perl

use strict;
use warnings;

use utf8;
use Web::Scraper;
use URI;
use YAML;
use DateTime;

my $stuff = URI->new(
    "http://www.nhk.or.jp/gogaku/english/business1/index.html"
);

my $scraper = scraper {
    process '//h1/img', 'title' => '@alt';
    process '//h1/img', 'image' => '@src';
    process '//div[@id="con-procontent"]/p[1]', 'description' => 'TEXT';
    #process '//div[@id="eng-bus-audionow"]/div[@class="eng-bus-audnwlink" and p ]',
    process '//div[@id="eng-bus-audionow"]/div[@class="eng-bus-audnwlink"]',
        'entry[]' => scraper {
            process '//a/text()', 'title' => 'TEXT';
            process '//a/text()', 'body' => 'TEXT';
            process '//a/text()', 'date' => ['TEXT', \&mk_date];
            process '//a', 'enclosure[]' => scraper {
                process '//a', 'url' => ['@href', \&to_string];
            };
        };
};

my $result = $scraper->scrape($stuff);
$result->{link} = $stuff;

binmode STDOUT, ":utf8";
print Dump $result;

sub to_string {
    $_->as_string;
}

sub mk_date {
    my $input = shift;
    return unless ($input =~ m!(\d+)月(\d+)日!);

    my $month = $1;
    my $day = $2;

    my $today = DateTime->now(time_zone => 'Asia/Tokyo')->truncate(to => 'day');
    my $this = $today->clone->set(month => $month, day => $day);
    my $last = $this->clone->subtract(years => 1);
    my $next = $this->clone->add(years => 1);
    my @date = sort { DateTime::Duration->compare($a->[1], $b->[1], $today) }
               map { [$_->[0], $_->[1]->is_positive ? $_->[1] : $_->[1]->inverse ] }
               map { [$_, $today - $_] } ($this, $last, $next);

    return $date[0]->[0]->ymd;
}