root/lang/perl/plagger/lib/Plagger/Rule/Candidates.pm @ 7640

package Plagger::Rule::Candidates;
use strict;
use base qw( Plagger::Rule );
use DB_File;

use UNIVERSAL::require;
use Readonly;
use Encode;
use Data::Dumper;

Readonly my %storage => (
    asis => 0,
    bdb => 'DB_File',
);

sub init {
    my $self = shift;

    my $friendly_storage_symbol = $self->{storage} || 'bdb';
    my $storage = $storage{$friendly_storage_symbol};
    Plagger->context->error("Unknown storage type $self->{storage}: $@") and die unless defined $storage;
    if ($storage) {
        $storage->require or Plagger->context->error("Error loading $storage: $@");
        tie my %dict, $storage, $self->{path}, O_RDWR|O_CREAT, 0600, $DB_BTREE
                or Plagger->context->error("Can't open $storage $self->{path}: $!");
        $self->{candidates} = \%dict;
    } else {
        my %hash;
        foreach my $cand (@{$self->{candidates}}) {
            $hash{encode('utf-8', $cand)} = 1;
        }
        $self->{candidates} = \%hash;
    }
}

sub dispatch {
    my($self, $args) = @_;
    my $value = eval $self->{property};
    if ($@) {
        Plagger->context->log(error => "Expression error: $@ with '$self->{property}'");
    }
    Plagger->context->log(debug => "Target value '$self->{property}' is " . Dumper($value));
    defined $self->{candidates}->{encode('utf-8', $value)};
}

1;

__END__

=head1 NAME

Plagger::Rule::Candidates

=head1 SYNOPSIS

    - module: Filter::Rule
      rule:
        - module: Candidates
          storage: bdb
          path: /path/to/berkeley/db/datafile
          property: 'split /, ?/, $args->{entry}->{body}


    - module: Filter::Rule
      rule:
        - module: Candidates
          storage: asis
          candidates:
            - foo
            - bar
          property: 'split /, ?/, $args->{entry}->{body}

=head1 DESCRIPTION

This rule mathces a feed when the C<property> of the feed is one of the C<candidates>,
where the C<property> of the feed is the evaluated value of C<property> option.

You can specify the C<candidates> through one of the followings:

=over 4

=item bdb

Berkeley DB (Btree)

=item asis

embeded in config.yaml

=back


=head1 AUTHOR

Yuki Sonoda (a.k.a. Yugui)

=head1 SEE ALSO

L<Plagger>, L<Plagger::Rule>

=cut