root/lang/ruby/mp1/mp1_parser_common.rl @ 36100

//
// MP1
//
// Copyright (C) 2008 FURUHASHI Sadayuki
//
//    Licensed under the Apache License, Version 2.0 (the "License");
//    you may not use this file except in compliance with the License.
//    You may obtain a copy of the License at
//
//        http://www.apache.org/licenses/LICENSE-2.0
//
//    Unless required by applicable law or agreed to in writing, software
//    distributed under the License is distributed on an "AS IS" BASIS,
//    WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
//    See the License for the specific language governing permissions and
//    limitations under the License.
//

%%{
        machine mp1_parser_common;

# primitive markers
        nil_marker                      = 0x00;
        false_marker            = 0x01;
        true_marker                     = 0x02;

# data type markers
        byte_marker                     = 0x04;
        int_marker                      = 0x05;
        float_marker            = 0x06;

# extend data type markers
        bignum_marker           = 0x10;
        byte_array_marker       = 0x11;

# container type markers
        array_marker            = 0x18;
        dictionary_marker       = 0x19;

        nil_type                        = nil_marker @nil_type;
        false_type                      = false_marker @false_type;
        true_type                       = true_marker @true_type;

        byte_type                       = byte_marker any @byte_type;
        int_type                        = int_marker any{4} @int_type;
        float_type                      = float_marker any{8} @float_type;

        byte_array_type         = byte_array_marker any{4} @byte_array_type;
        bignum_type                     = bignum_marker any{2} @bignum_type;

        array_type                      = array_marker any{4} @array_type;
        dictionary_type         = dictionary_marker any{4} @dictionary_type;

        primitive_types = nil_type | false_type | true_type;

        data_types = byte_type | int_type | float_type;

        extend_types = bignum_type | byte_array_type;

        container_types = array_type | dictionary_type ;

        value_type =
                primitive_types |
                data_types |
                extend_types |
                container_types
                ;

main := (value_type);

array_item := (value_type %array_item)*;

dictionary_item := ((value_type %dictionary_key_item) (value_type %dictionary_value_item))*;

byte_array_item := (any @byte_array_item)*;

bignum_item := (any @bignum_item)*;

}%%