root/lang/vb2005/FuwaKumo/trunk/FuwaKumo/WebAccessBase.vb @ 33664

Imports System.Net

Public MustInherit Class WebAccessBase
    Protected Shared _proxy As System.Net.WebProxy = Nothing
    Protected Shared _proxyType As ProxyTypeEnum = ProxyTypeEnum.IE
    Protected Shared _defaultTimeOut As Integer = 20000

    Public Enum ProxyTypeEnum
        None
        IE
        Specified
    End Enum

    Protected Enum WEBACCESS_REQ_TYPE
        ReqGET
        ReqPOST
    End Enum

    Public Sub New()
        ServicePointManager.Expect100Continue = False
        With SettingNet.Instance
            _proxyType = .ProxyType
            _proxy = .Proxy
            _defaultTimeOut = .TimeOut
        End With
    End Sub

    Protected Shared Function CreateRequestObject(ByVal reqType As WEBACCESS_REQ_TYPE, _
                                            ByVal url As System.Uri, _
                                            ByVal param As System.Collections.Generic.SortedList(Of String, String)) As HttpWebRequest
        Dim ub As New System.UriBuilder(url.AbsoluteUri)
        If reqType = WEBACCESS_REQ_TYPE.ReqGET Then
            ub.Query = CreateQueryString(param)
        End If
        Dim webReq As HttpWebRequest = CType(WebRequest.Create(ub.Uri), HttpWebRequest)
        If reqType = WEBACCESS_REQ_TYPE.ReqGET Then
            webReq.Method = "GET"
        Else
            webReq.Method = "POST"
            webReq.ContentType = "application/x-www-form-urlencoded"
            Using writer As New System.IO.StreamWriter(webReq.GetRequestStream)
                writer.Write(CreateQueryString(param))
            End Using
        End If
        webReq.Timeout = _defaultTimeOut
        If _proxyType <> ProxyTypeEnum.IE Then webReq.Proxy = _proxy

        Return webReq
    End Function

    Protected Shared Function CreateQueryString(ByVal param As System.Collections.Generic.SortedList(Of String, String)) As String
        If param Is Nothing OrElse param.Count = 0 Then Return String.Empty

        Dim query As New System.Text.StringBuilder
        For Each key As String In param.Keys
            query.AppendFormat("{0}={1}&", UrlEncode(key), UrlEncode(param(key)))
        Next
        Return query.ToString(0, query.Length - 1)
    End Function

    Protected Shared Function ParseQueryString(ByVal queryString As String) As System.Collections.Specialized.NameValueCollection
        Dim query As New System.Collections.Specialized.NameValueCollection
        Dim parts() As String = queryString.Split("&"c)
        For Each part As String In parts
            Dim index As Integer = part.IndexOf("="c)
            If index = -1 Then
                query.Add(Uri.UnescapeDataString(part), "")
            Else
                query.Add(Uri.UnescapeDataString(part.Substring(0, index)), Uri.UnescapeDataString(part.Substring(index + 1)))
            End If
        Next
        Return query
    End Function

    Protected Shared Function UrlEncode(ByVal str As String) As String
        Const _unreservedChars As String = "abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789-_.~"
        Dim sb As New System.Text.StringBuilder
        Dim bytes As Byte() = System.Text.Encoding.UTF8.GetBytes(str)

        For Each b As Byte In bytes
            If _unreservedChars.IndexOf(Chr(b)) <> -1 Then
                sb.Append(Chr(b))
            Else
                sb.appendformat("%{0:X2}", b)
            End If
        Next
        Return sb.ToString()
    End Function

    Private Shared Function GetResponse(Of T)(ByVal webRequest As HttpWebRequest, _
                                        ByRef statusCode As HttpStatusCode, _
                                        ByVal encode As System.Text.Encoding, _
                                        ByVal headerInfo As System.Collections.Specialized.NameValueCollection _
                                    ) As T

        Dim webRes As HttpWebResponse = Nothing
        Try
            webRes = CType(webRequest.GetResponse(), HttpWebResponse)

            If headerInfo IsNot Nothing AndAlso headerInfo.Count > 0 Then
                For Each key As String In headerInfo.Keys
                    If Array.IndexOf(webRes.Headers.AllKeys, key) > -1 Then
                        headerInfo(key) = webRes.Headers.Item(key)
                    Else
                        headerInfo(key) = ""
                    End If
                Next
            End If

            statusCode = webRes.StatusCode
            If statusCode = HttpStatusCode.MovedPermanently OrElse _
               statusCode = HttpStatusCode.Found OrElse _
               statusCode = HttpStatusCode.SeeOther OrElse _
               statusCode = HttpStatusCode.TemporaryRedirect Then
                If GetType(T).Name = GetType(String).Name Then
                    Return CType(webRes.Headers.Item("Location"), Object)
                Else
                    Return Nothing
                End If
            End If

            Using strm As System.IO.Stream = webRes.GetResponseStream()
                Select Case GetType(T).Name
                    Case GetType(System.Drawing.Bitmap).Name
                        Return CType(New System.Drawing.Bitmap(strm), Object)
                    Case GetType(String).Name
                        Using sr As New System.IO.StreamReader(strm, encode)
                            Return CType(sr.ReadToEnd(), Object)
                        End Using
                    Case Else
                        Throw New System.ArgumentException("Type must String or Bitmap")
                End Select
            End Using
        Catch ex As System.Net.WebException
            Throw
        Catch ex As Exception

        Finally
            If webRes IsNot Nothing Then
                webRes.Close()
            End If
        End Try
    End Function

    Protected Shared Function GetText(ByVal webRequest As HttpWebRequest, _
                                        ByRef statusCode As HttpStatusCode, _
                                        ByVal encode As System.Text.Encoding, _
                                        ByVal headerInfo As System.Collections.Specialized.NameValueCollection _
                                    ) As String
        Try
            Return GetResponse(Of String)(webRequest, statusCode, encode, headerInfo)
        Catch ex As Exception
            Throw
        End Try
    End Function

    Protected Shared Function GetText(ByVal webRequest As HttpWebRequest, _
                                        ByRef statusCode As HttpStatusCode, _
                                        ByVal headerInfo As System.Collections.Specialized.NameValueCollection _
                                    ) As String
        Try
            Return GetText(webRequest, statusCode, System.Text.Encoding.UTF8, headerInfo)
        Catch ex As Exception
            Throw
        End Try
    End Function

    Protected Shared Function GetText(ByVal webRequest As HttpWebRequest, _
                                        ByRef statusCode As HttpStatusCode _
                                    ) As String
        Try
            Return GetText(webRequest, statusCode, Nothing)
        Catch ex As Exception
            Throw
        End Try
    End Function

    Protected Shared Function GetImage(ByVal webRequest As HttpWebRequest, _
                                        ByRef statusCode As HttpStatusCode _
                                    ) As System.Drawing.Bitmap
        Try
            Return GetResponse(Of System.Drawing.Bitmap)(webRequest, statusCode, Nothing, Nothing)
        Catch ex As Exception
            Throw
        End Try
    End Function
End Class