root/lang/vim/tvitter/trunk/tvitter.vim @ 5990

" A Twitter client plugin for Vim
" Maintainer: Yuki Mitsui <silphire@gmail.com>
" License: distributed under the same terms of Vim itself
" Created: 2008-01-20
" Version: 0.2
"

" if !has('ruby')
"       echoerr 'missing Ruby interface.'
"       exit
" endif

command! -nargs=* Tw :call s:Twitter(<q-args>)

" 
function! s:UrlEscape(str)
        " convert to UTF-8
        let l:u8str = a:str
        if &encoding != 'utf-8'
                if has('iconv')
                        let l:u8str = iconv(a:str, &encoding, 'utf-8')
                else
                        echoerr 'missing iconv interface. compile with iconv or use UTF-8 encoding.'
                endif
        endif
        let l:escstr = ''
        let l:i = 0
        while l:i < strlen(l:u8str)
                if l:u8str[l:i] =~# '[0-9A-Za-z_\-\.]'
                        let l:escstr .= l:u8str[l:i]
                elseif l:u8str[l:i] == ' '
                        let l:escstr .= '+'
                elseif l:u8str[l:i] == '+'
                        let l:escstr .= '%2B'
                else
                        let l:byte = char2nr(l:u8str[l:i])
                        let l:escstr .= "%"
                        let l:escstr .= '0123456789ABCDEF'[l:byte / 0x10]
                        let l:escstr .= '0123456789ABCDEF'[l:byte % 0x10]
                endif
                let l:i += 1
        endwhile
        return l:escstr
endfunction

"
function! s:UrlCharUnEscape(ch)
endfunction

"
function! s:UrlUnEscape(str)
endfunction

"
function! s:GetMail()
        if !exists("g:tvitter_mail") || strlen(g:tvitter_mail) == 0
                let g:tvitter_mail = input("mail: ")
        endif
endfunction

" 
function! s:GetPassword()
        if !exists("g:tvitter_pass") || strlen(g:tvitter_pass) == 0
                let g:tvitter_pass = inputsecret("password: ")
        endif
endfunction

"
function! s:CheckLength(msg)
        let l:len = strlen(a:msg)
        if l:len > 140
                let l:answer = input("Overlong update (".l:len." bytes). Really send? ")
                if(strlen(l:answer) > 0 && l:answer[0] == 'y')
                        return 1
                else
                        return 0
                endif
        endif
        return 1
endfunction

" 
function! s:ReflectResult(response)
        echo a:response
        if split(a:response, ' ')[1] == '200'
                return 1
        else
                unlet g:tvitter_mail
                unlet g:tvitter_pass
                return 0
        endif
endfunction

"
function! s:UpdateStatus(msg)
        call s:GetMail()
        call s:GetPassword()

        if !s:CheckLength(a:msg)
                return
        endif

        let l:status = s:UrlEscape(a:msg)
        let l:result = ''
        if executable('curl')
                let l:result = system('curl -s -D- -u '.g:tvitter_mail.':'.g:tvitter_pass.' http://twitter.com/statuses/update.json -d "status='.l:status.'"')
        elseif executable('wget')
                let l:result = system('wget -q -O- --save-headers --user='.g:tvitter_mail.' --password='.g:tvitter_pass.' http://twitter.com/statuses/update.json --post-data="status='.l:status.'"')
        else
                echoerr "either curl or wget is required"
        endif

        call s:ReflectResult(split(l:result, '\n')[0])
endfunction

"
function! s:ReadFriendStatus()
        call s:GetMail()
        call s:GetPassword()

        if executable('curl')
                let l:result = system('curl -s -D- -u '.g:tvitter_mail.':'.g:tvitter_pass.' http://twitter.com/statuses/friends_timeline.json')
        elseif executable('wget')
                let l:result = system('wget -q -O- --save-headers --user='.g:tvitter_mail.' --password='.g:tvitter_pass.' http://twitter.com/statuses/friends_timeline.json')
        else
                echoerr "either curl or wget is needed"
        endif
        let l:elems = split(l:result, '\n')
        if s:ReflectResult(l:elems[0])
                let null = 'null'
                let true = 'true'
                let false = 'false'
                execute 'let l:status='.l:elems[-1]
                unlet null, true, false
        endif
endfunction

" Post an entry to Twitter
function! s:Twitter(msg)
        if strlen(a:msg) == 0
                " entry list
                call s:ReadFriendStatus()
        else
                " post a comment
                call s:UpdateStatus(a:msg)
        endif
endfunction