root/lang/xslt/misc/svnlog2atom.xsl @ 1598

<?xml version="1.0" encoding="UTF-8"?>
<?comment
Usage:
in zsh (for process replacement)
xsltproc --stringparam user yoko svnlog2atom.xsl =(svn log --xml -v http://svn.coderepos.org/share/)
?>
<xsl:stylesheet version="1.0"
        xmlns="http://www.w3.org/2005/Atom"
        xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
        exclude-result-prefixes=""
        xml:lang="ja">

        <xsl:output
                method="xml"
                encoding="UTF-8"
                omit-xml-declaration="no"
                indent="yes"
                />

        <xsl:param name="user" select="'cho45'"/>
        <xsl:param name="trac" select="'http://coderepos.org/share/'"/>
        <xsl:param name="linkbase" select="'http://coderepos.org/share/wiki/Committers/'"/>

        <xsl:strip-space elements="*" />

        <xsl:template match="/">
                <feed xmlns="http://www.w3.org/2005/Atom">
                        <title>User feed of <xsl:value-of select="$user"/></title>
                        <link href="{$linkbase}{$user}"/>
                        <updated>
                                <xsl:for-each select="log/logentry[author = $user]">
                                        <xsl:sort select="@revision" order="descending" />
                                        <xsl:if test="position() = 1">
                                                <xsl:value-of select="date"/>
                                        </xsl:if>
                                </xsl:for-each>
                        </updated>
                        <author>
                                <name><xsl:value-of select="$user"/></name>
                        </author>
                        <id>
                                <xsl:value-of select="$linkbase"/>
                                <xsl:value-of select="$user"/>
                        </id>

                        <xsl:apply-templates select="log/logentry[author = $user]">
                                <xsl:sort select="@revision" order="descending" />
                        </xsl:apply-templates>
                </feed>
        </xsl:template>

        <xsl:template match="logentry">
                <entry>
                        <title>
                                <xsl:text>Revision:</xsl:text>
                                <xsl:value-of select="@revision"/>
                        </title>
                        <link href="{$trac}changeset/{@revision}"/>
                        <id>
                                <xsl:value-of select="$trac"/>
                                <xsl:text>changeset/</xsl:text>
                                <xsl:value-of select="@revision"/>
                        </id>
                        <updated><xsl:value-of select="date"/></updated>
                        <summary>
                                <xsl:value-of select="msg"/>
                        </summary>
                        <content type="xhtml">
                                <div xmlns="http://www.w3.org/1999/xhtml">
                                        <ul class="changes">
                                                <xsl:for-each select="paths/path">
                                                        <li>
                                                                <xsl:text>[</xsl:text>
                                                                <xsl:value-of select="@action"/>
                                                                <xsl:text>] </xsl:text>
                                                                <xsl:value-of select="."/>
                                                        </li>
                                                </xsl:for-each>
                                        </ul>
                                        <pre class="message">
                                                <xsl:value-of select="msg"/>
                                        </pre>
                                </div>
                        </content>
                </entry>
        </xsl:template>


</xsl:stylesheet>