root/lang/xslt/misc/svnlog2atom.xsl @ 1602

<?xml version="1.0" encoding="UTF-8"?>
<?comment
Usage:
in zsh (for process replacement)
xsltproc --stringparam user yoko svnlog2atom.xsl =(svn log --xml -v http://svn.coderepos.org/share/)
?>
<xsl:stylesheet version="1.0"
        xmlns="http://www.w3.org/2005/Atom"
        xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
        exclude-result-prefixes=""
        xml:lang="ja">

        <xsl:output
                method="xml"
                encoding="UTF-8"
                omit-xml-declaration="no"
                indent="yes"
                />

        <xsl:param name="user" select="'cho45'"/>
        <xsl:param name="uribase" select="'http://coderepos.org/'"/>
        <xsl:param name="trac" select="concat($uribase, 'share/')"/>
        <xsl:param name="linkbase" select="concat($trac, 'wiki/Committers/')"/>

        <xsl:strip-space elements="*"/>

        <xsl:template match="/">
                <feed xmlns="http://www.w3.org/2005/Atom">
                        <title>User feed of <xsl:value-of select="$user"/></title>
                        <link href="{$linkbase}{$user}" type="application/atom+xml"/>
                        <updated>
                                <xsl:for-each select="log/logentry[author = $user]">
                                        <xsl:sort select="@revision" order="descending" data-type="number"/>
                                        <xsl:if test="position() = 1">
                                                <xsl:value-of select="date"/>
                                        </xsl:if>
                                </xsl:for-each>
                        </updated>
                        <author>
                                <name><xsl:value-of select="$user"/></name>
                                <uri>
                                        <xsl:value-of select="$linkbase"/>
                                        <xsl:value-of select="$user"/>
                                </uri>
                        </author>
                        <id>
                                <xsl:value-of select="$linkbase"/>
                                <xsl:value-of select="$user"/>
                        </id>
                        <generator uri="http://svn.coderepos.org/share/lang/xslt/misc/svnlog2atom.xsl">Subversion with XSLT (svnlog2atom.xsl)</generator>

                        <xsl:apply-templates select="log/logentry[author = $user]">
                                <xsl:sort select="@revision" order="descending" data-type="number"/>
                        </xsl:apply-templates>
                </feed>
        </xsl:template>

        <xsl:template match="logentry">
                <xsl:if test="position() &lt; 20">
                        <entry>
                                <title>
                                        <xsl:text>Revision:</xsl:text>
                                        <xsl:value-of select="@revision"/>
                                </title>
                                <link href="{$trac}changeset/{@revision}" type="text/html"/>
                                <id>
                                        <xsl:value-of select="$trac"/>
                                        <xsl:text>changeset/</xsl:text>
                                        <xsl:value-of select="@revision"/>
                                </id>
                                <updated><xsl:value-of select="date"/></updated>
                                <summary>
                                        <xsl:value-of select="msg"/>
                                </summary>
                                <content type="xhtml" xml:base="{$uribase}">
                                        <div xmlns="http://www.w3.org/1999/xhtml">
                                                <ul class="changes">
                                                        <xsl:for-each select="paths/path">
                                                                <li>
                                                                        <xsl:text>[</xsl:text>
                                                                        <xsl:value-of select="@action"/>
                                                                        <xsl:text>] </xsl:text>
                                                                        <xsl:value-of select="."/>
                                                                </li>
                                                        </xsl:for-each>
                                                </ul>
                                                <pre class="message">
                                                        <xsl:value-of select="msg"/>
                                                </pre>
                                        </div>
                                </content>
                        </entry>
                </xsl:if>
        </xsl:template>


</xsl:stylesheet>