root/platform/air/Whony/src/model/threads/LocalizeImageThread.as @ 35391

/*
 * Whony - Wassr Client Software
 * 
 * Licensed under the MIT License
 * 
 * Copyright (c) 2009 Kazushi tominaga (Seacolor)
 *                    CodeRepos  (coderepos.org)
 * 
 * Permission is hereby granted, free of charge, to any person obtaining a copy
 * of this software and associated documentation files (the "Software"), to deal
 * in the Software without restriction, including without limitation the rights
 * to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
 * copies of the Software, and to permit persons to whom the Software is
 * furnished to do so, subject to the following conditions:
 * 
 * The above copyright notice and this permission notice shall be included in
 * all copies or substantial portions of the Software.
 * 
 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
 * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
 * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
 * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
 * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
 * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN
 * THE SOFTWARE.
 * 
 */
package model.threads 
{
        import com.adobe.net.URI;
        import flash.filesystem.File;
        import flash.filesystem.FileStream;
        import flash.utils.ByteArray;
        import model.ModelLocator;
        import org.httpclient.http.Get;
        import org.httpclient.HttpClient;
        import org.libspark.thread.Thread;
        import org.libspark.thread.utils.Executor;
        import org.libspark.thread.utils.ParallelExecutor;
        import flash.filesystem.FileMode;
        import mx.logging.ILogger;
        import mx.logging.Log;
        import mx.utils.ObjectUtil;
        
        /**
         * ...
         * @author Kazushi Tominaga (Seacolor)
         */
        public class LocalizeImageThread extends Thread
        {
                protected const logger:ILogger = Log.getLogger(className);
                protected var locator:ModelLocator = ModelLocator.instance;
                
                public function LocalizeImageThread(htmlText:String, pattern:RegExp, callback:Function = null, httpClient:HttpClient = null) 
                {
                        logger.debug("constructor({0})", arguments);
                        _htmlText = htmlText;
                        _pattern = pattern;
                        _callback = callback;
                        _httpClient = httpClient;
                }
                
                protected var _htmlText:String;
                protected var _pattern:RegExp;
                protected var _callback:Function;
                protected var _httpClient:HttpClient;
                
                override protected function run():void 
                {
                        logger.debug("method run({0})", arguments);
                        imgUrls = _htmlText.match(_pattern);
                        
                        var getImgUrls:Array = new Array();
                        
                        if (imgUrls != null) {
                                getImgUrls = imgUrls.filter(function(item:*, index:int, array:Array):Boolean {
                                        return !locator.emojiMap.hasOwnProperty(item);
                                });
                        }
                        
                        if (!getImgUrls.length) {
                                replace();
                                //next(replace);
                                return;
                        }
                        
                        _executor = new ParallelExecutor();
                        
                        for each (var imgUrl:String in getImgUrls) {
                                _executor.addThread(new HttpClientThread(new URI(imgUrl), new Get(), 60000, _httpClient));
                        }
                        
                        _executor.start();
                        _executor.join();
                        
                        next(complete);
                        interrupted(cancel);
                }
                
                protected var imgUrls:Array;
                
                protected var _executor:Executor;
                
                protected function complete():void {
                        logger.debug("method complete({0})", arguments);
                        
                        if (!LocalizeImageThread.tempDirectory) {
                                LocalizeImageThread.tempDirectory = File.applicationStorageDirectory.resolvePath(PATH_EMOJI);
                        }
                        
                        for (var i:int = 0; i < _executor.numThreads; i++) {
                                var thread:HttpClientThread = HttpClientThread(_executor.getThreadAt(i));
                                var bytes:ByteArray = thread.bytes;
                                
                                var emoji:File = new File(LocalizeImageThread.tempDirectory.url + "/" + thread.uri.getFilename());
                                logger.debug("emoji.exists: {0}", emoji.exists);
                                if (!emoji.exists) {
                                        var fileStream:FileStream = new FileStream();
                                        try 
                                        {
                                                fileStream.open(emoji, FileMode.WRITE);
                                                fileStream.writeBytes(bytes);
                                        } finally {
                                                fileStream.close();
                                        }
                                }
                                locator.emojiMap[thread.uri.toString()] = PATH_EMOJI + emoji.name;
                        }
                        
                        replace();
                        //next(replace);
                }
                
                protected static const PATH_EMOJI:String = "emoji/";
                
                protected static var tempDirectory:File;
                
                protected function cancel():void {
                        _executor.interrupt();
                }
                
                protected function replace():void {
                        logger.debug("method replace({0})", arguments);
                        
                        //var rtnHtmlText:String = _htmlText;
                        if (imgUrls) {
                                for each (var url:String in imgUrls) {
                                        _htmlText = _htmlText.replace(url, locator.emojiMap[url]);
                                }
                        }
                        
                        if (_callback != null) _callback.apply(this, [_htmlText]);
                }
        }
        
}