root/websites/coderepos.org/feedmaker/lib/FeedMaker/C/Default.pm @ 9944

package FeedMaker::C::Default;

use strict;
use warnings;
use base qw( FeedMaker );

use Data::CodeRepos::CommitPing;
use DateTime;
use Encode ();
use YAML ();

use XML::Feed;
use XML::Feed::Entry;

sub do_default {
    my $self = shift;
    $self->res->body('ok');
    return unless $self->req->address eq '202.228.221.240';

    my $commit = eval { Data::CodeRepos::CommitPing->new($self->req) };
    return if $@;

    my $log = YAML::LoadFile($self->config->{log});
    unshift @$log, $commit;
    pop @$log if @$log > $self->config->{max};
    YAML::DumpFile($self->config->{log}, $log);

    my $feed = XML::Feed->new('RSS');
    $feed->title('CodeRepos Timeline');
    $feed->link('http://coderepos.org/share/');
    $feed->modified(DateTime->now( time_zone => 'local' ));
    $feed->generator("CodeRepos FeedMaker/$FeedMaker::VERSION");
    $feed->description('');
    $feed->author('yappo');

    for my $rev (@$log) {
        my $changes_base = $rev->changes_base;
        my $changes_base_txt = (ref $changes_base eq 'ARRAY') ? join(', ', @$changes_base) : $changes_base;
        my $comment = Encode::decode('utf-8', $rev->comment);

        my $entry = XML::Feed::Entry->new('RSS');
        $entry->title(sprintf 'r%s: %s: %s', $rev->rev, $changes_base_txt, @{ split /\n/, $comment }[0]);
        $entry->link('http://coderepos.org/share/changeset/' . $rev->rev);
        $entry->issued($rev->date);
        $entry->modified($rev->date);
        $entry->author($rev->author);

        $changes_base_txt =~ s/, / /g;
        $entry->category($changes_base_txt);
        $entry->content('<div>'.$comment.'</div><div><ul>' . join('', map { '<li>'.$_->{status}.':'.$_->{path}.'</li>' } @{ $rev->files }) . '</ul></div>');

        $feed->add_entry($entry);
    }

    my $xml = $feed->as_xml;
    utf8::decode($xml) unless utf8::is_utf8($xml);
    open my $output, ">:utf8", $self->config->{feed} or return;
    print $output $xml;
    close $output;
}

1;

=head1 NAME

FeedMaker::C::Default - Soozy Component

=head1 SYNOPSIS

See L<FeedMaker>

=head1 DESCRIPTION

Soozy Component

=head1 AUTHOR

Default Author

=head1 LICENSE

This library is free software, you can redistribute it and/or modify
it under the same terms as Perl itself.

=cut